批处理：复制上次修改时间为 15 分钟前的文件

Question

我有一个自动创建文件的文件夹，我需要每 5 分钟复制一次新文件（即最后一次修改是在最后 5 分钟内的文件）。

 :loop
for %a in (C:\test\*) do (
 set FileDate=%~ta
)
 timeout /t 300
 goto loop

这就是我发现获取文件日期的方式，但我不知道如何比较并获得当前日期少于 5 分钟。

（复制命令不是必需的，因为是通过 SSH 并且此问题已解决）。

Answer 1

在批处理中，日期时间计算是一项非常繁琐的任务。

我建议使用 PowerShell（至少作为一种工具）

获取最近 5 分钟在当前目录中创建的文件。
此 powershell 命令将输出类似dir的列表：

Get-ChildItem -Path 'X:\path'|Where-Object {((Get-Date) - $_.LastWriteTime).TotalMinutes -le 5}

要将其限制为仅 FullName，您可以附加管道

| Select-Object -ExpandProperty FullName

或者简单地将命令括在括号中并附加 (...).FullName

(Get-ChildItem -Path 'X:\path'|Where-Object {((Get-Date) - $_.LastWriteTime).TotalMinutes -le 5}).FullName

---

包裹成一批

:: Q:\Test\2018\11\08\SO_53206386.cmd
@Echo off
for /f "usebackq delims=" %%A in (`
  powershell -Nop -C "(Get-ChildItem -Path 'X:\path' -File |Where-Object {((Get-Date) - $_.LastWriteTime).TotalMinutes -le 15}).FullName"
`) Do Echo %%A

此批次的示例输出（列表本身）

> SO_53206386.cmd
Q:\Test\2018\11\08\SO_53206386.cmd

-File参数需要 PowerShell v3+，但可以用另一个管道命令替换

| Where-Object {!($PSISContainer)}

过滤掉文件夹。 （相反的是-Directory or no ! for not）

@Echo off
for /f "usebackq delims=" %%A in (`
  powershell -Nop -C "(Get-ChildItem -Path 'X:\path' | Where-Object {!($PSISContainer)}| Where-Object {((Get-Date) - $_.LastWriteTime).TotalMinutes -le 15}).FullName"
`) Do Echo %%A

Answer 2

这是一个完全不同的解决方案，很可能导致相同的行为，其优点是文件的最后修改日期并不重要。 因此，如果将文件复制到观察文件夹中，即使其最后修改时间不在最后X分钟内，也会对其进行处理。 每次在文件夹中创建文件或文件被进程修改时，它都会自动使用 Windows 设置的存档文件属性。

@echo off
set "Folder=C:\test"
:loop
for /F "eol=| delims=" %%I in ('dir "%Folder%\*" /AA-D-H /B /ON 2^>nul') do (
    %SystemRoot%\System32\attrib.exe -a "%Folder%\%%I"
    echo Copy the file "%Folder%\%%I"
)
%SystemRoot%\System32\timeout.exe /T 300
goto loop

命令FOR在后台以cmd.exe /C启动的单独命令进程中执行以下命令行。

dir "C:\test\*" /AA-D-H /B /ON 2>nul

命令DIR输出

• 由于/B ，仅以裸格式显示文件名和文件扩展名
• 由于/AA-DH ，仅具有归档属性集的非隐藏文件
• 由于/ON按文件名排序（实际上不需要）
• 在目录C:\test中找到匹配通配符模式* 。

DIR在找不到任何符合这些要求的目录条目时输出的错误消息通过将其从句柄STDERR重定向到设备NUL来抑制。

阅读有关使用命令重定向运算符的 Microsoft 文章，了解2>nul的说明。 重定向运算符>必须在FOR命令行上使用脱字符^进行转义，以便在 Windows 命令解释器在执行命令FOR之前处理此命令行时解释为文字字符，该命令使用在后台启动的单独命令进程执行嵌入式dir命令行。

这个DIR在单独的命令过程中的输出被FOR捕获并逐行处理。

FOR总是跳过空行，这里不会出现。

FOR也默认跳过以分号开头的行（文件名）。 通过使用eol=|更改禁用此行为默认的行尾字符; 到任何文件名都不能有的竖线。

FOR默认使用空格/制表符作为分隔符拆分子字符串（标记）中的行，并将第一个空格/制表符分隔的字符串分配给指定的循环变量I 。 此处不需要此行为，因为文件名可以包含一个或多个空格。 出于这个原因， delims=用于指定一个空的分隔符列表，该列表禁用行拆分行为。

因此，分配给循环变量I的是带有文件扩展名的文件名，由DIR输出，没有路径。

命令ATTRIB用于从当前文件中删除归档属性，以用于 FOR循环的下一次迭代。 然后可以将文件复制到不同的位置或进行处理，否则不会修改其内容。

要了解使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• attrib /?
• dir /?
• echo /?
• for /?
• goto /?
• timeout /?