Haskell函数:: [Name]-> [[（（Name，Bool）]]

Question

给定以下内容：

type Name = String
envs :: [Name] -> [[(Name , Bool)]]

我必须实现“ envs”，以便给定名称列表，它返回名称和布尔值的所有可能组合

我的尝试并未返回所有可能的组合，这是我的代码：

envs xxs@(x:xs) = [[ (name, value) | name <- xxs  , value <- [False, True] ]]

的预期结果

envs ["P", "Q"]

是：

[ [ ("P",False)
  , ("Q",False)
  ]
, [ ("P",False)
  , ("Q",True)
  ]
, [ ("P",True)
  , ("Q",False)
  ]
, [ ("P",True)
  , ("Q",True)
  ]
]

但是，我的是：

[[("P",True),("Q",True)],[("P",False),("Q",False)]]

那么，“ envs”函数的正确实现是什么，即返回预期结果的函数呢？

Answer 1

你想要做的就是让所有的组合True和False了名的数量，它可以很容易地做到replicateM专门到列表：

replicateM (length names) [False, True]

例如，如果length names == 2 ，则产生：

[ [False, False]
, [False, True]
, [True, False]
, [True, True]
]

剩下的只是用名称本身来压缩每个名称：

envs names =
  [ zip names values
  | let n = length names
  , values <- replicateM n [False, True]
  ]

对于envs ["P", "Q"]会产生：

[ [("P", False), ("Q", False)]
, [("P", False), ("Q", True)]
, [("P", True), ("Q", False)]
, [("P", True), ("Q", True)]
]

它适用于任意数量的输入，甚至0，由于您不匹配[] ，您的原始实现可能会失败。 它总是返回2 ^n个分配：

-- 2^0 == 1
envs [] == [[]]

-- 2^3 == 8
envs ["P", "Q", "R"] ==
  [ [("P", False), ("Q", False), ("R", False)]
  , [("P", False), ("Q", False), ("R", True)]
  , [("P", False), ("Q", True), ("R", False)]
  , [("P", False), ("Q", True), ("R", True)]
  , [("P", True), ("Q", False), ("R", False)]
  , [("P", True), ("Q", False), ("R", True)]
  , [("P", True), ("Q", True), ("R", False)]
  , [("P", True), ("Q", True), ("R", True)]
  ]