操作 Haskell Monad 状态

Question

有点类似于这个问题，我试图弄清楚如何在 Haskell Monad 状态中移动。 团队中的每个Employee都被相应的Employee'替换，同时保持一些简单的状态。 这是代码：

module Main( main ) where
import Control.Monad.State

data Employee  = EmployeeSW  Int Int | EmployeeHW Int String deriving ( Show )
data Employee' = EmployeeSW'     Int | EmployeeHW'    String deriving ( Show )

scanTeam :: [Employee] -> State (Int,Int) [Employee']
scanTeam [    ] = return []
scanTeam (p:ps) = scanEmployee p -- : scanTeam ps ???

scanEmployee :: Employee -> State (Int,Int) Employee'
scanEmployee (EmployeeSW id s) = do
    (num,raise) <- get
    put (num+1,raise)
    return (EmployeeSW' (s+raise))
scanEmployee (EmployeeHW id s) = do
    (num,raise) <- get
    put (num+1,raise)
    return (EmployeeHW' (s++(show raise)))

startState = (0,3000)

t = [(EmployeeHW 77 "Hundred"),(EmployeeSW 66 500),(EmployeeSW 32 200)]

main = print $ evalState (scanTeam t) startState

我想最终将scanEmployee p与scanTeam ps连接scanEmployee p ，所以我尝试提取scanEmployee p各个部分，并以某种方式将它们与scanTeam ps粘合在一起。 到目前为止，我失败得很惨。 实际上，我什至不确定状态是否可以在它们之间移动（？）。

Answer 1

由于State是一个 monad，您可以使用do表示法来定义State计算。 （ State的Monad实例会检测状态，因此do块中一个语句的结束状态成为下一个语句的开始状态。）

因此，在do块中，我将：

1. 处理列表中的第一个Employee以获得一个新的Employee
2. 递归处理列表的其余部分
3. 把这两个结果一起回来，并用它们作为返回值State FUL计算。

scanTeam :: [Employee] -> State (Int,Int) [Employee']
scanTeam [    ] = return []
scanTeam (p:ps) = do
    newP <- scanEmployee p
    newPs <- scanTeam ps
    return (newP:newPs)

事实证明，“在 monadic 上下文中map ”通常非常有用，因此它作为mapM :: Monad m => (a -> mb) -> [a] -> m [b] ( aka traverse :: (Traversable t, Applicative f) => (a -> fb) -> ta -> f (tb) ，如果你准备好进入兔子洞的话）。

scanTeam = mapM scanEmployee