Excel-从另一个单元格更改一个单元格的值，但清除输入单元格后更改的单元格将保留值

Question

我基本上是想制作一个输入单元格。 我想要的是当我更改C2的值时，它更改了C1的值。 但是，当我擦除C2时，我希望C1保留该值。

因此，如果我使C2 =“ Adam”，C1 =“ Adam”，但是随后我将C2 =“”更改为C1仍然是“ Adam”。

谁能帮我这个忙吗？ 我一直在网上寻找很长一段时间，找不到任何可以帮助我找到解决方案的东西。

Answer 1

您可以在Worksheet_Change事件上执行此操作，

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row = 2 And Target.Column = 3 Then    'C2
        If Target.Value <> "" Then
            Range("C1").Value = Target.Value
        End If
    End If
End Sub

公式=C2或某些变体将不起作用，因为它无法记住此后已删除的值。

---

我想您可以伪造一个类似于以下内容的公式 ，但是我绝对不建议这样做，尤其是与代码结合使用时。 我只是出于兴趣而发布它。

Private Sub Worksheet_Change(ByVal Target As Range)
    Static old As String

    If Target.Row = 2 And Target.Column = 3 Then    'C2
        If Target.Value <> "" Then
            Range("C1").Formula = "=IF(N(""""),"""","""")&C2"
            old = Target.Value
        Else
            Range("C1").Formula = "=IF(N(""" & old & """),"""","""")& """ & old & """"
        End If

    End If
End Sub

这毫无意义，因为您仍然需要代码。

---

我想代码甚至可能只写一个公式然后引用的命名范围/值：

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Value <> "" Then
        ActiveWorkbook.Names.Add Name:="stored", RefersToR1C1:="=""" & Target.Value & """"
    End If
End Sub

Answer 2

我们可以使用Event Macro来做到这一点。 将以下代码放在工作表代码区域中：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim C1 As Range, C2 As Range
    Set C1 = Range("C1")
    Set C2 = Range("C2")

    If Intersect(Target, C2) Is Nothing Then Exit Sub
    If C2.Value = "" Then Exit Sub

    Application.EnableEvents = False
        C2.Copy C1
    Application.EnableEvents = True
End Sub

因为它是工作表代码，所以非常易于安装和自动使用：

1. 右键单击Excel窗口底部附近的选项卡名称
2. 选择查看代码-这将打开一个VBE窗口
3. 将内容粘贴并关闭VBE窗口

如果您有任何疑问，请先在试用版工作表上尝试一下。

如果您保存工作簿，则宏将随其一起保存。 如果您在2003年以后使用Excel版本，则必须将文件另存为.xlsm而不是.xlsx

删除宏：

1. 如上调出VBE窗口
2. 清除代码
3. 关闭VBE窗口

要总体上了解有关宏的更多信息，请参见：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参见：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其正常工作！