如何使用VBA / Excel通过IE自动执行数据输入过程？

Question

我对VBA非常满意，并且正在尝试使用VBA在Excel中设置宏表以部分自动化我公司的手动数据输入过程，以帮助减少时间和错误成本。

成功的脚本将完成以下任务：

1. 启动IE并导航到指定的网站。
2. 使用提供的凭据登录。
3. 在具有唯一ID的字段中输入值，然后按“下一步”按钮
4. 在200个字段中输入相应的数据，每个字段具有唯一的ID（例如LastName_0对应于单元格A2，LastName_1对应于A3等）

目前，我仅完成了步骤1，其中脚本启动IE并导航到有问题的网站（ https://iapps.courts.state.ny.us/chrs/SignIn ），但是，我正在运行尝试插入网站的用户名和密码时出现错误438（对象不支持此属性或方法）。

我尝试了在Google搜索中找到的多个不同的代码，所有代码均返回相同的错误。 目前，我在宏工作簿的第2页上列出了用户名和密码，如代码中所引用。 由于我缺乏知识，我不确定我的错误在哪里。

作为参考，我们在VBA 7.1，Excel 2013和IE 11上运行。

Sub login()

    Const Url$ = "https://iapps.courts.state.ny.us/chrs/SignIn"

    Dim UserName As String, Password As String, LoginData As Worksheet
    Set LoginData = ThisWorkbook.Worksheets("Sheet2")
    UserName = LoginData.Cells(1, "B").Value
    Password = LoginData.Cells(2, "B").Value

    Dim ie As Object
    Set ie = CreateObject("InternetExplorer.Application")

    With ie

        .navigate Url
        ieBusy ie
        .Visible = True

        Dim oLogin As Object, oPassword As Object
        Set oLogin = .document.getElementsByName("txtUserName")(0) 
{This is where the 438 error occurs ^}
        Set oPassword = .document.getElementsByName("pwPassword")(0)

        oLogin.Value = UserName
        oPassword.Value = Password
        .document.forms(0).submit

    End With

End Sub

Sub ieBusy(ie As Object)
    Do While ie.Busy Or ie.readyState < 4
        DoEvents
    Loop
End Sub

当前，工作表2的设置是在单元格B1中设置用户ID，在单元格B2中设置密码。

预期的结果将是成功登录，这时我将努力确定要遵循的页面和实际数据输入页面的代码。

Answer 1

使用适当的页面加载等待。 使用ID及其更快。 我使用css id选择器，例如#txtUserName ，它与getElementById等效，但速度更快。

Option Explicit
'VBE > Tools > References: Microsoft Internet Controls
Public Sub Login()
    Dim ie As InternetExplorer
    Const URL As String = "https://iapps.courts.state.ny.us/chrs/SignIn"
    Dim userName As String, password As String, loginData As Worksheet

    Set ie = New InternetExplorer
    Set loginData = ThisWorkbook.Worksheets("Sheet2")
    userName = loginData.Cells(1, "B").Value
    password = loginData.Cells(2, "B").Value

    With ie
        .Visible = True
        .Navigate2 URL

        While .Busy Or .readyState < 4: DoEvents: Wend

        With .document
            .querySelector("#txtUserName").Value = userName
            .querySelector("#pwPassword").Value = password
            .querySelector("#btnSubmit").Click
        End With

        Stop
    End With
End Sub