将值从30本书复制到一本书-Excel VBA

Question

我正在尝试将值从30本书的excel复制到另一本书excel，但是由于它们的名称不同，我不确定如何引用这30本书。而且我不知道如何引用我想要的excel文件关。

我正在从excel书中运行宏，它将具有其他excel的所有值。

我的问题是：

1. 不知道如何引用即将打开的Excel工作簿，因为它们的名称不同。
2. 如何使用偏移量粘贴值。

我有以下代码：

      Sub MacroPrueba4()

    'Paso 1: Declarar las variables

     Dim Archivos As String
     Dim vals As Variant


       Worksheets("Hoja1").Range("A3:A7").Copy
        vals = Worksheets("Hoja1").Range("A2:F14").Value

     Archivos = Dir("C:\Users\fernandofernandez\Desktop\Prueba\*.xlsx")
     Do While Archivos <> “”


     'Paso 3: Open the books one by one

     Workbooks.Open "C:\Users\fernandofernandez\Desktop\Prueba\" & Archivos

    'code

        vals = Worksheets(1).Range("E2").Value


 ' this is something i use to paste the format of the last column format

    Workbooks("libro2").Range("C10").End(xlToRight).Select
    Selection.EntireColumn.Select
    Selection.Copy
    ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).Select
    Selection.EntireColumn.Select
    ActiveSheet.Paste
    'Selection.Paste

' this is where I will paste de value

' is this right??
ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).Select
 Selection.Value = vals


     'this close the active excel, but I think it would close the excel that I am pasting the values, because it would be the activeworkbook. I want to close only the 30 excels that will open in the loop.

     ActiveWorkbook.Close SaveChanges:=True



     Archivos = Dir
     Loop
    End Sub

Answer 1

函数Workbooks.Open返回工作簿打开状态，因此您可以编写：

my_workbook = Workbooks.Open "C:\Users\fernandofernandez\Desktop\Prueba\" & Archivos

' Your code

my_workbook.Close SaveChanges:=True

这样，您可以确定您关闭了正确的书。 对于分配值，如果您想要干净的代码，请不要使用select 。

你可以做 ：

ActiveSheet.Range("C10").End(xlToRight).Offset(0, 1).value = vals

别客气。

Answer 2

合并文件夹中所有工作簿中的数据。

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

有关所有详细信息，请参见下面的链接。

https://www.rondebruin.nl/win/s3/win008.htm

您可能还想考虑一下该实用程序。

https://www.rondebruin.nl/win/addins/rdbmerge.htm