Terraform：如何从 VPC id 获取 VPC CIDR？

Question

我正在尝试为给定 VPC 获取PIV4_CIDR ，使用 aws_vpcs 数据源首先识别 VPC 并从 ID 获取 CIDR - 可能吗？

只是一点背景，出于某种设计原因，我们在不同的 VPC 中有服务。 说，例如。 我有三个 VPC： xxxprod-n 、 xxxprod-l和xxxprod-h ，我想为整个子网添加 SG 规则以允许访问特定端口。 这是我尝试过的：

data "aws_vpcs" "prod" {
  tags = {
    Name = "${var.project}prd-*"
  }
}

resource "aws_security_group_rule" "pa-allow" {
  count             = length(data.aws_vpcs.prod.ids)
  type              = "ingress"
  from_port         = 8140
  to_port           = 8140
  protocol          = "tcp"
  cidr_blocks       = [sort(data.aws_vpcs.prod.ids)[count.index].cidr_block]
  security_group_id = aws_security_group.secg.id
  description       = "allow from ${sort(data.aws_vpcs.prod.ids)[count.index]}"
}

我得到错误：

错误：不支持的属性

在../../modules/mgt/ec2.tf 第 42 行，在资源“aws_security_group_rule”“pa-allow”中：42：cidr_blocks = [sort(data.aws_vpcs.prod.ids)[count.index].cidr_block ]

该值没有任何属性。

I tried that, based on this page: https://www.terraform.io/docs/providers/aws/d/vpc.html , thinking aws_vpc and aws_vpcs will do similar sort of thing but it seem doesn't. 知道我该怎么做吗？

Answer 1

您可以使用data.aws_vpcs获得vpc的SET （而非列表）。 （我认为文档是错误的...）然后，您可以使用data.aws_vpcs获取data.aws_vpc列表，并可以获取其中的cidr块。

data "aws_vpcs" "prod" {
  tags = {
    Name = "${var.project}prd-*"
  }
}

data "aws_vpc" "prod" {
  count = length(data.aws_vpcs.prod.ids)
  id    = tolist(data.aws_vpcs.prod.ids)[count.index]
}

resource "aws_security_group_rule" "pa-allow" {
  count             = length(data.aws_vpcs.prod.ids)
  type              = "ingress"
  from_port         = 8140
  to_port           = 8140
  protocol          = "tcp"
  cidr_blocks       = [data.aws_vpc.prod[count.index].cidr_block]
  security_group_id = aws_security_group.secg.id
  description       = "allow from ${tolist(data.aws_vpcs.prod.ids)[count.index]}"
}

Answer 2

至于今天，您不再需要使用列表方法，文档中未指定它，但您可以执行以下操作：

data "aws_vpc" "main" {
  id = <your_vpc_id>
}

然后您可以访问它data.aws_vpc.main.cidr_block ，它没有在属性referece 中指定，但它就在那里。

Terraform 版本：1.0.11

AWS 提供商版本：4.9.0