Oracle nvl2 在存储过程 PLS-00201 中不起作用：必须声明标识符“NVL2”

Question

作为标题，我正在写一些关于 Oracle 的存储过程，首先我检查了版本

SELECT * FROM v$version;

结果

Oracle Database 11g Enterprise Edition Release 11.2.0.4.0 - 64bit Production
PL/SQL Release 11.2.0.4.0 - Production
CORE    11.2.0.4.0  Production
TNS for Linux: Version 11.2.0.4.0 - Production
NLSRTL Version 11.2.0.4.0 - Production

...

并且，尝试使用常规 SQL 查询 NVL2

select 'Test: ' || nvl2('...', 'things', 'nothing') from dual;
select 'Test: ' || nvl2('', 'things', 'nothing') from dual;

结果似乎是正确的

Test: things
Test: nothing

...

所以我确认 11g 确实支持 NLV2 功能，我现在可以开始编写我的存储过程，如下所示：

create or replace procedure my_schema.SP_READ_MEMBER(noP in varchar2, nameP in varchar2, idNoP in varchar2, birthdayP in varchar2, resultP out sys_refcursor)
is
v_prg_name varchar2(20) := 'SP_READ_MEMBER';
sys_sql    varchar2(1000);

begin
  Insertlog(SYSDATE, v_prg_name, '1.0 Start');
  sys_sql :=  sys_sql || 'select a.no, a.name, a.id_no, to_char(a.birthday, ''yyyy/MM/dd'') as birthday, ''REGISTERED'' as type, email, mobile from rep where 1=1 ';
  sys_sql :=  sys_sql || nvl2(noP,'and no='''|| noP ||'''', ''); --PLS-00201

  open resultP for sys_sql;
  Insertlog(SYSDATE, v_prg_name, '2.0 Finished w/o error');

  exception
  when others then
    declare
      error_time VARCHAR2(30) := RTRIM(TO_CHAR(SYSDATE, 'YYYY/MM/DD, HH24:MI:SS'));
      error_code NUMBER := SQLCODE;
      error_msg  VARCHAR2(300) := SQLERRM;
    begin
      rollback;
      DBMS_OUTPUT.PUT_LINE(error_time || ',' || TO_CHAR(error_code) || ',' || error_msg);
      Insertlog(SYSDATE, v_prg_name,  error_msg || ', 3.0 ERROR, sql:' || sys_sql);
    end;
end;
/

Oracle 告诉我它编译出错，这是

PLS-00201：必须声明标识符“NVL2”

函数如何在常规查询中工作，但在存储过程中未声明？

Answer 1

NVL2在SQL中有效，但在PL / SQL中无效。

并非每个SQL关键字都可以在PL / SQL中使用，这很愚蠢，但是之前已经发生过几次。 Oracle一直在逐步统一SQL和PL / SQL，并且他们最终可能会使用此功能。 目前，我认为My Oracle Support文档Note 359506.1 Pls-00201 Assigning The Result of NVL2() To A Variable In a PLSQL Block解决此问题。 尽管该文档不可用，即使对于具有支持访问权限的人员也是如此。

目前，我建议使用其他语法。 就个人而言，我发现CASE版本更加清晰，即使它有点冗长。

更改：

sys_sql :=  sys_sql || nvl2(noP,'and no='''|| noP ||'''', '');

至：

sys_sql :=  sys_sql || case when nop is not null then 'and no='''|| noP ||'''' else '' end;

Answer 2

NVL2 适用于 SQL，但不适用于 PL/SQL。

改变：

sys_sql :=  sys_sql || nvl2(noP,'and no='''|| noP ||'''', '');

到：

select sys_sql || nvl2(noP,'and no='''|| noP ||'''', '') into sys_sql from dual;