erlang 将消息从服​​务器传递到不同的节点

Question

我试图让一个简单的 erlang 服务器在我尝试注册服务器的地方工作，将消息传递给应该在不同节点上注册和创建 2 个进程的服务器，但我收到此错误：

{badarg,[{erlang,register,[printer1,<12172.86.0>],[]},
         {testerl,server,1,[{file,"testerl.erl"},{line,13}]}]}

我的代码：

-module(testerl).
-export([start_server/1,
    server/1,
    printer/0
    ]).


server(Node_1) ->
    receive
        finished ->
            exit(normal);
        {Message} ->
            register(printer1, spawn(Node_1, testerl, printer, [])),
            register(printer2, spawn(Node_1, testerl, printer, [])),
            {printer1, Node_1} ! {Message},
            {printer2, Node_1} ! {Message},
            server(Node_1)
    end.

printer() ->
    receive
        finished->
            exit(normal);
        {Message} ->
            io:format("printer received msg ~p~n", [Message]),
            server ! finished   
    end.

start_server(Node_1) ->
    register(server, spawn(testerl, server, [Node_1])).

我可以使用 erl -sname [name] 启动 2 个节点，使用另一个节点的名称启动服务器，但是当我尝试使用服务器传递消息时！ “一些消息”它崩溃了。 我在这里做错了什么？ 我如何注册一个进程并调用它以便它在另一台机器上执行？

Answer 1

您收到 badarg 错误是因为您试图通过 erlang:register/2 注册非本地 Pid。

文档 ( http://erlang.org/doc/man/erlang.html ) 指出：

badarg
    If PidOrPort is not an existing local process or port.

您的 spawn(Node_1,...) 的结果是另一个节点（即 Node_1）上的 Pid。 如果要注册非本地 Pid，可以使用 global:register_name。

所以：

-module(testerl).
-export([start_server/1,
    server/1,
    printer/0
    ]).

server(Node_1) ->
  receive
    finished ->
      exit(normal);
    {Message} ->
      global:register_name(printer1, spawn(Node_1, testerl, printer, [])),
      global:register_name(printer2, spawn(Node_1, testerl, printer, [])),
      global:send(printer1, {Message}),
      global:send(printer2, {Message}),
      server(Node_1)
    end.

printer() ->
    receive
        finished->
            exit(normal);
        {Message} ->
            io:format("printer received msg ~p~n", [Message]),
            global:send(server, finished)   
    end.
start_server(Node_1) ->
    global:register_name(server, spawn(testerl, server, [Node_1])).

运行这个，我得到：

(node1@f0189805e911)59> testerl:start_server('node2@f0189805e911').
(node1@f0189805e911)60> yes
(node1@f0189805e911)61> global:send(server,{test}).                
(node1@f0189805e911)62> printer received msg test
(node1@f0189805e911)63> printer received msg test

当然，不需要使用注册进程：

-module(testerl).
-export([start_server/1,
    server/3,
    printer/1
    ]).

server(Node_1, P1, P2) ->
  receive
    finished ->
      exit(normal);
    {Message} ->
      P1 !  {Message},
      P2 !  {Message},
      server(Node_1, P1, P2)
    end.

printer(ServerPid) ->
    receive
        finished->
            exit(normal);
        {Message} ->
            io:format("printer received msg ~p~n", [Message]),
            ServerPid ! finished   
     end.
start_server(Node_1) ->
  P1 =  spawn(Node_1, testerl, printer, [self()]),
  P2 =  spawn(Node_1, testerl, printer, [self()]),
  spawn(testerl, server, [Node_1, P1, P2]).

运行这个：

(node1@f0189805e911)14> Pid = testerl:start_server('node2@f0189805e911').
<0.117.0>
(node1@f0189805e911)15> Pid ! {test}.                                         
{test}
printer received msg test
printer received msg test
(node1@f0189805e911)16> 

Answer 2

为了使这成为可能，您需要使用Distributed Erlang 。 为了在节点之间传递消息，它们需要集群。 这是通过使用 cookie 来完成的。 为了说明这一点，我将使用来自LYSE的示例（Fred Hèbert，2013 年）。

首先我们启动两个节点

erl -sname node1 -setcookie 'asd11'
erl -sname node2 -setcookie 'asd11'

检查节点是否已连接net_kernel:connect_node('node2@polar') 。

我们在两者上注册了一个控制台进程本身

(node1@polare)1> register(server, self()).
(node2@polare)1> register(client, self()).

我们将让服务器回答来自客户端的传入消息。 在 node1 上我们做

receive {hello, from, OtherShell} -> OtherShell ! <<"hey there!">> end.

现在可以从客户端发送消息。

{server, node1@polar} ! {hello, from, self()}.

在第一个节点上，您应该看到<<"hey there!">>打印在其控制台中。