Excel VBA PasteSpecial xlPasteValues 语法错误

Question

我试图将数据从一个 .xlsx 文件复制到我的 .xlsm 文件，但没有格式化。 当我尝试使用以下代码行时，出现未指定的语法错误。

TargetSheet.Range("A" & TargetLastRow).PasteSpecial xlPasteValues（或各种其他形式）

Sub Import_Click()

'Set the target workbook for import.'
Dim TargetWorkbook As Workbook
Set TargetWorkbook = Application.ActiveWorkbook

'Prompt window for user to select and import file.'
Dim UserFilename As String
UserFilename = Application.GetOpenFilename

Dim UserWorkbook As Workbook
Set UserWorkbook = Application.Workbooks.Open(UserFilename)

'Copy data from source to target sheet.'
Dim SourceSheet As Worksheet
Set SourceSheet = UserWorkbook.Worksheets(1)

Dim TargetSheet As Worksheet
Set TargetSheet = TargetWorkbook.Worksheets(1)

Dim SourceLastRow As Long
SourceLastRow = SourceSheet.Cells(SourceSheet.Rows.Count, "A").End(xlUp).Row

Dim TargetLastRow As Long
TargetLastRow = TargetSheet.Cells(TargetSheet.Rows.Count, "A").End(xlUp).Offset(1).Row

SourceSheet.Range("A2:S" & SourceLastRow).Copy _
TargetSheet.Range("A" & TargetLastRow)

'Close import workbook.'
UserWorkbook.Close

End Sub

Answer 1

您可以通过将目的地作为.Copy第一个参数来.Copy

SourceSheet.Range("A2:S" & SourceLastRow).Copy Destination:=TargetSheet.Range("A" & TargetLastRow)

或者，如果您想使用 SpecialPaste，则需要在 2 个单独的语句中进行：

SourceSheet.Range("A2:S" & SourceLastRow).Copy 'no destination given here
'separate statement for pasting:
TargetSheet.Range("A" & TargetLastRow).PasteSpecial xlPasteValues

请注意，在.Copy行的末尾不能有_作为行连接.Copy ！

Answer 2

我会尽量避免使用复制和粘贴，替换行

SourceSheet.Range("A2:S" & SourceLastRow).Copy _
TargetSheet.Range("A" & TargetLastRow)

使用下一个代码

TargetSheet.Range("A" & TargetLastRow).Resize(SourceLastRow - 1, _
        SourceSheet.Range("A2:S" & SourceLastRow).Columns.count) = _
                        SourceSheet.Range("A2:S" & SourceLastRow)