从 Inno Setup 执行带有输出重定向的程序

Question

我正在尝试在卸载时进行数据库备份，但由于某种原因，带有重定向的程序在 Inno Setup 中总是失败。 这是我所拥有的：

[Run]
Filename: "{#DB_PATH}\mysqldump.exe"; \
  Parameters: "-c --compact {#DB_NAME} > {#STORAGE_PATH}\db.sql";  Flags: runhidden;
Filename: "xcopy";                     \
  Parameters: "{#STORAGE_PATH} {userdesktop}\Backup\ /E/H"; Flags: runhidden;
Filename: "{#DB_PATH}\mysqladmin.exe"; \
  Parameters: "shutdown"; Flags: runhidden;

最后两个命令正常工作。 但由于某种原因，第一个永远不会奏效。 我已经测试了该命令，它可以正常工作。

我不确定我是否做错了什么，所以感谢任何帮助。

Answer 1

这似乎是以下情况的变体：
Inno Setup 中的输出重定向如何工作？

有一点不同，您使用的是[Run]部分而不是 Pascal Script 代码。

输出重定向语法是命令提示符的一项功能，而不是核心 Windows API。 因此，如果要重定向输出，则需要通过{cmd} /c actual-command-line > output-file调用命令。

所以应该是：

Filename: "{cmd}"; \
  Parameters: "/C {#DB_PATH}\mysqldump.exe -c --compact {#DB_NAME} > {#STORAGE_PATH}\db.sql"; \
  Flags: runhidden;

但是您也应该引用所有路径（并且由于cmd.exe使用的语法晦涩，您还需要引用整个命令）：

Filename: "{cmd}"; \
  Parameters: "/C """"{#DB_PATH}\mysqldump.exe"" -c --compact {#DB_NAME} > ""{#STORAGE_PATH}\db.sql"""""; \
  Flags: runhidden;