vb.net 设置数据源到组合框

Question

我想在我运行时为我的组合框设置一个数据源，但没有错误，但它一直在组合框中显示零

Dim cnx As New MySqlConnection("datasource=localhost;database=bdgeststock;userid=root;password=")
        Dim cmd As MySqlCommand = cnx.CreateCommand
        Dim da As MySqlDataAdapter
        Dim ds As New DataSet
        If ConnectionState.Open Then
            cnx.Close()
        End If
        cnx.Open()
        cmd.CommandText = "SELECT idf,(prenom + ' ' + nom) AS NAME FROM fournisseur "
        da = New MySqlDataAdapter(cmd)
        cnx.Close()
        da.Fill(ds)
        da.Dispose()
        ComboBox1.DataSource = ds.Tables(0)
        ComboBox1.ValueMember = "idf"
        ComboBox1.DisplayMember = "NAME"

Answer 1

对于 ComboBox 数据源，您可能不需要繁重的数据集或数据表 - 普通对象的集合就可以完成这项工作。

另一种方法是将表示逻辑移至 vb.net 代码，而让 sql server 仅执行持久性逻辑。

Public Class Fournisseur
    Public ReadOnly Property Id As Integer
    Public ReadOnly Property Name As String  

    Public Sub New(id As Integer, prenom As String, nom As String)
        Id = id
        Name = $"{pronom} {nom}".Trim()
    End Sub
End Class

您可以创建专用函数来加载数据

Private Function LoadItems() As List(Of Fournisseur)
    Dim query = "SELECT idf, prenom, nom FROM fournisseur"

    Using connection As New MySqlConnection(connectionString)
        Using command As New MySqlCommand(query, connection)
            connection.Open()
            Dim items = new List(Of Fournisseur)()

            Using reader AS MySqlDataReader = command.ExecuteReader()
                While reader.Read()
                    Dim item As New Fournisseur(
                        reader.GetInt32(0),
                        reader.GetString(1),
                        reader.GetString(2)
                    )

                    items.Add(item)
                End While
            End Using

            Return items
        End Using
    End Using
End Function

然后使用看起来很简单

ComboBox1.ValueMember = "Id"
ComboBox1.DisplayMember = "Name"
ComboBox1.DataSource = LoadItems()

Answer 2

我认为问题出在您的 sql 中，而 mysql 正在对 prenom 和 nom 执行某种数字加法并产生 0

尝试

CONCAT(prenom, ' ', nom) as name

在你的 sql 中。 我更喜欢在大多数 RDBMS 中使用 concat 来连接字符串，因为它更符合它在 NULL 上的行为 - 在 sqlserver 中，在诸如'a' + null类'a' + null东西上使用加号的 concat 运算符会导致 NULL 但在 oracle 'a' || null 'a' || null是a - 在两个 CONCAT 行为中是一致的

这是包含我所有建议的完整代码：

Dim cnstr = "datasource=localhost;database=bdgeststock;userid=root;password="
Dim cmd = "SELECT idf, CONCAT(prenom, ' ', nom) AS nom FROM fournisseur "
Using da As New MySqlDataAdapter(cmd, cnstr)
    Dim dt As New DataTable
    da.Fill(dt)
    ComboBox1.DataSource = dt
    ComboBox1.ValueMember = "idf"
    ComboBox1.DisplayMember = "nom"
End Using

提示：

• 您不需要弄乱连接：dataadapter 将为您创建/打开/关闭它
• 使用数据表而不是数据集
• 使用 使用
• 使用 MySqlDataAdapter 的构造函数，它接受一个连接字符串和一个命令文本——在这种情况下更短更接近。 如果我在事务等中手动注册多个命令，我只使用带有 DbConnection 的构造函数