如何根据列行数据复制粘贴到文本文件中并保存

Question

我有一个关于将数据从 Excel 表保存到 a.txt 文件的问题。 我需要从我的工作簿的 R 列和 R 列中的每个单元格复制每个单元格，以创建一个 .txt 文件，粘贴数据，并根据同一行列 A 数据保存它。 这将为 R 列中的每个行项目创建一个文本文件，并根据相同的行列 A 值命名文件。 我对 VBA 的经验有限。 以下是数据样本。

Answer 1

下面是一些 VBA 循环遍历工作表上的所有行，在以 A 列中的数据命名的指定文件夹中创建一个文本文件，并将 R 列中的数据写入它。

Sub sSaveData(strFolder As String)
    On Error GoTo E_Handle
    Dim strFile As String
    Dim intFile As Integer
    Dim lngLastRow As Long
    Dim lngLoop1 As Long
    Dim ws As Worksheet
    Set ws = Worksheets("Sheet1")
    If Right(strFolder, 1) <> "\" Then strFolder = strFolder & "\"
    lngLastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    For lngLoop1 = 1 To lngLastRow
        strFile = strFolder & ws.Cells(lngLoop1, 1) & ".txt"
        intFile = FreeFile
        Open strFile For Output As intFile
        Print #intFile, ws.Cells(lngLoop1, 18)
        Close #intFile
    Next lngLoop1
sExit:
    On Error Resume Next
    Set ws = Nothing
    Reset
    Exit Sub
E_Handle:
    MsgBox Err.Description & vbCrLf & "sSaveData", vbOKOnly + vbCritical, "Error: " & Err.Number
    Resume sExit
End Sub

问候，