无法为扩展“应用程序”设置未知属性“mainClass”

Question

我在我的项目中使用 Gradle 6.1 版。

该项目的build.gradle如下所示：

plugins {
    id 'application'
}

application {
    mainClass = 'com.mytestproject.Main'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

group 'com.mytestproject'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

但是当我运行这个命令./gradlew assemble时，它给了我下面给出的错误：

./gradlew assemble

FAILURE: Build failed with an exception.

* Where:
Build file '/com/myproject/build.gradle' line: 6

* What went wrong:
A problem occurred evaluating root project 'JavaTestProject'.
> Could not set unknown property 'mainClass' for extension 'application' of type org.gradle.api.plugins.internal.DefaultJavaApplication.

* Try:
Run with --stacktrace option to get the stack trace. Run with --info or --debug option to get more log output. Run with --scan to get full insights.

* Get more help at https://help.gradle.org

BUILD FAILED in 484ms

Answer 1

将 build.gradle修改为：

apply plugin: "application"

mainClassName = "com.mytestproject.Main"

sourceCompatibility = 1.8
targetCompatibility = 1.8

group 'com.mytestproject'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.12'
}

运行这个命令： ./gradlew build

Answer 2

你可以试试这个（基于源代码）：

application {
    setMainClassName("some.package.Main")
}

Answer 3

6.4 中引入了弃用。 它来自：

 application {
   mainClassName = "com.foo.bar.FooBar"
 }

至：

 application {
   mainClass.set("com.foo.bar.FooBar")
 }

文档：

https://docs.gradle.org/current/javadoc/org/gradle/api/plugins/JavaApplication.html#getMainClassName--