[英]Why CTRL+C is not working on TMemo component? (Vista + Delphi 7)
[英]How do I handle Ctrl+C in a Delphi console application?
是否有可用的最佳实践和代码片段来展示我如何在 Delphi 控制台应用程序中处理 Ctrl+C?
我找到了一些文章,这些文章提供了一些关于调试器可能出现的问题的信息,包括异常处理、DLL 卸载、标准输入关闭和终结,例如这个 CodeGear 论坛线程。
来自 Windows API( MSDN ):
BOOL WINAPI SetConsoleCtrlHandler(
PHANDLER_ROUTINE HandlerRoutine, // address of handler function
BOOL Add // handler to add or remove
);
HandlerRoutine function 是控制台进程指定的 function,用于处理进程接收到的控制信号。 function 可以有任何名称。
BOOL WINAPI HandlerRoutine(
DWORD dwCtrlType // control signal type
);
在 Delphi 中,处理程序例程应如下所示:
function console_handler( dwCtrlType: DWORD ): BOOL; stdcall;
begin
// Avoid terminating with Ctrl+C
if ( CTRL_C_EVENT = dwCtrlType ) then
result := TRUE
else
result := FALSE;
end;
我写了一个小程序来告诉你如何正确地停止后台任务。 希望它更清楚。
ThreadConsoleApplication.dpr 文件的内容:
program ThreadConsoleApplication;
{$APPTYPE CONSOLE}
uses
SysUtils,
Windows,
Classes;
type
{ **
* Classe TQueueReaderTestApplication
* }
TThreadConsoleApplication = class(TThread)
public
procedure Execute; override;
constructor Create; virtual;
destructor Destroy; override;
class function getInstance: TThreadConsoleApplication;
end;
function TThreadConsoleApplication_consoleCtrlHandler(dwCtrlType: DWORD): BOOL;
stdcall; forward;
{ **
* Classe TQueueReaderTestApplication
* }
constructor TThreadConsoleApplication.Create;
begin
inherited Create(True { CreateSuspended } );
Windows.setConsoleCtrlHandler(@TThreadConsoleApplication_consoleCtrlHandler,
True { add } );
end;
var
threadConsoleApplicationInstance: TThreadConsoleApplication = nil;
destructor TThreadConsoleApplication.Destroy;
begin
threadConsoleApplicationInstance := nil;
inherited;
end;
procedure TThreadConsoleApplication.Execute;
begin
System.Writeln('[TThreadConsoleApplication.Execute] begin');
try
while not Terminated do
begin
System.Writeln('[TThreadConsoleApplication.Execute] running ...');
Windows.Sleep(1000 { dwMilliseconds } );
end;
finally
System.Writeln('[TThreadConsoleApplication.Execute] end');
end;
end;
class function TThreadConsoleApplication.getInstance: TThreadConsoleApplication;
begin
if nil = threadConsoleApplicationInstance then
begin
threadConsoleApplicationInstance := TThreadConsoleApplication.Create;
end;
Result := threadConsoleApplicationInstance;
end;
function TThreadConsoleApplication_consoleCtrlHandler(dwCtrlType: DWORD): BOOL;
begin
Result := False;
if Windows.CTRL_C_EVENT = dwCtrlType then
begin
TThreadConsoleApplication.getInstance.Terminate;
Result := True;
end;
end;
var
thread: TThread;
begin
System.Writeln('[program] begin');
try
thread := nil;
try
thread := TThreadConsoleApplication.getInstance;
thread.Resume;
System.Writeln('[program] press a CTRL+C to stop running');
thread.WaitFor;
finally
thread.Free;
end;
System.Writeln('[program] end');
except
on E: Exception do
begin
System.Writeln(System.ErrOutput, '[program] end with error');
System.Writeln(System.ErrOutput, E.ClassName, ': ', E.Message);
end;
end;
System.Writeln('[program] press a key to quit');
System.Readln;
end.
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.