F# - 为什么我不能在此代码中使用管道运算符？

Question

我可能在这里遗漏了一些非常基本的东西，但我无法弄清楚它是什么。

我有一些非常基本的代码如下：

let myList = [1; 3; 5; 7; 5; 3; 9; 5; 2; 5; 3; 8]
let fiveOrLess = myList |> List.choose (fun number ->
    match number with
    | number when number <= 5 -> Some number
    | _ -> None)

......正如预期的那样，效果很好。

但是，在下面的代码中，我已将“myList”从 pipe 移至“普通”参数，我从编译器收到两条错误消息：

let myList = [1; 3; 5; 7; 5; 3; 9; 5; 2; 5; 3; 8]
let fiveOrLess = List.choose (fun number ->
    match number with
    | number when number <= 5 -> Some number
    | _ -> None) myList

错误 FS3118 值不完整或 function 定义。 如果这是在表达式中，则表达式的主体必须缩进到与“let”关键字相同的列。 [第二个'let'上的这个错误。]

错误 FS0010 绑定中的意外标识符。 在此点或其他标记处或之前预期的不完整结构化构造。 [这个错误在最后一个“myList”上。]

这些错误消息对我来说没有多大意义，因为我所做的只是将参数“从一侧移动到另一侧”。

此处的文档： https://msdn.microsoft.com/visualfsharpdocs/conceptual/list.choose%5b%27t%2c%27u%5d-function-%5bfsharp%5d显示的代码与我的第二个示例具有非常相似的形式但这没问题。

谁能解释我在这里犯了什么愚蠢的基本错误？ 此外，可能更重要的是，任何人都可以解释错误消息的含义以及为什么我会收到它们，无论是在一般情况下还是在这种情况下？

Answer 1

这是一个相当微妙的格式问题，但似乎在多行 lambda（从let行开始）之后立即将参数放在同一行上是无效的。 您的代码以几种不同的方式具有非标准格式，但 F# 编译器一直相当宽松，直到最后一部分解析器完全失去对事物的跟踪并且无法提供有用的错误。

所以这并不是说您的格式明显“错误”，而是一旦您养成按照正常格式标准编写 F# 代码的习惯，您就永远不会遇到这个问题。 以下是格式化 function 的一些标准方法：

let fiveOrLess =
    List.choose
        (fun number ->
            match number with
            | number when number <= 5 -> Some number
            | _ -> None)
        myList

上面的缩进清楚地表明了 List.choose 的两个List.choose是什么。

---

let fiveOrLess =
    myList
    |> List.choose (fun number ->
        match number with
        | number when number <= 5 -> Some number
        | _ -> None)

我们在上面使用管道，因此多行 lambda 是最后一个参数。

Answer 2

您面临的问题是缩进。

尝试进一步缩进，如下所示：

let myList = [1; 3; 5; 7; 5; 3; 9; 5; 2; 5; 3; 8]
let fiveOrLess = List.choose (fun number ->
      match number with
      | number when number <= 5 -> Some number
      | _ -> None) myList

另请注意，在这种情况下，您可以使用function关键字

let myList = [1; 3; 5; 7; 5; 3; 9; 5; 2; 5; 3; 8]
let fiveOrLess = List.choose (function
        | number when number <= 5 -> Some number
        | _ -> None) myList

最后，除非这是一个简化的重现，否则filter就是你的 function 在这种情况下：

let myList = [1; 3; 5; 7; 5; 3; 9; 5; 2; 5; 3; 8]
let fiveOrLess = List.filter (fun n -> n <= 5) myList