批处理文件 - 使用 dir /s /b %~dp0 获取文件列表并从 output 中删除 %~dp0 的路径

Question

ECHO ===FILES TO TRANSFER===
FOR /f "usebackq tokens=*" %%G IN (`DIR /B /S "%~dp0Files"`) DO @ECHO %%G

output 是文件/目录的完整路径，但我想通过从 output 中删除 %~dp0 的路径来使其更简单

Answer 1

只需从每个条目中删除%~dp0 （注意：这不适用于%%G元变量，您必须使用“正常”环境变量）：

@echo off
setlocal enabledelayedexpansion
ECHO ===FILES TO TRANSFER===
FOR /f "usebackq tokens=*" %%G IN (`DIR /B /S "%~dp0"`) DO (
  set "file=%%G"
  echo !file:%~dp0=!
)

Answer 2

这是我建议您合并的方法，它可以保护可能包含的文件名! 字符并将 output 限制为文件，根据您的要求：

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
For /F Delims^=^ EOL^= %%G In ('Dir /B/S/A-D "%~dp0Files" 2^>NUL')Do (
    Set "_=%%G" & SetLocal EnableDelayedExpansion
    Echo(!_:*%~dp0Files=.! & EndLocal)
Pause

如果您不想使用相对路径类型 output 则更改:_.*%~dp0Files=.! 到:_:*%~dp0Files\=!

---

或者，您可以使用较慢的forfiles.exe实用程序获取相对路径：

%__AppDir__%forfiles.exe /P "%~dp0Files" /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE Echo @RelPath"

如果您更喜欢没有双引号的情况，那么此修改应该这样做：

%__AppDir__%forfiles.exe /P "%~dp0Files" /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE For %%G In (@RelPath)Do Echo %%~G"

如果你想要它没有前导.\那么也许：

%__AppDir__%forfiles.exe /P "%~dp0Files" /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE For /F 0x22Tokens=1*Delims=\0x22 %%G In (@RelPath)Do Echo %%H"

您也可以通过利用powershell.exe来做到这一点：

%__AppDir__%WindowsPowerShell\v1.0\powershell.exe -NoProfile Get-ChildItem -Path "%~dp0Files" -File -Force -Name -Recurse

这可以做到， （不推荐） ，在短短的一行：

powershell -NoP ls "%~dp0Files" -File -Fo -Na -Rec

Answer 3

要在不进行字符串操作的情况下检索给定根目录的相对路径，您可以使用带有/L选项的xcopy命令，该命令列出了在不使用/L的情况下将复制的文件的相对路径：

pushd "%~dp0" && (
    for /F "delims= eol=|" %%G in ('xcopy /L /S /Y /I "Files" "%TEMP%" ^| find "\"') do (
        echo(%%G
    )
    popd
)

pushd和popd分别用于切换到根目录和从根目录返回。

find命令用于抑制xcopy的摘要行# File(s) 。