简单现金簿中总计的数组公式

Question

我正在尝试创建一个简单的arrayformula来保持现金簿中的运行记录。 很简单，但让我难住了。 这是一个基本表：

	一个	乙	C
1	在	出去	全部的
2
3	10		10
4		1	9
5	7		16
6	5		21
7		4	17

因此，例如要在单元格 C3 中生成总数，我使用公式offset(C3,-1,0)-B3+A3但我想我可以将它包装在arrayformula中，所以它变成arrayformula(offset(C3:C,-1,0)-B3:B+A3:A)但它会出错并且需要一个额外的行，这会无休止地进行。

任何帮助都会很棒。

Answer 1

• 使用两个运行总计： IN和OUT并从IN中减去OUT

• 创建运行总计的经典数组公式解决方案是使用带有可变字符串（相对于range参数）的 SUMIF 作为criterion

   =ARRAYFORMULA(SUMIF(ROW(A2:A7),"<="&ROW(A2:A7),A2:A7)-SUMIF(ROW(A2:A7),"<="&ROW(A2:A7),B2:B7))

• 开放范围版本：

   =ARRAY_CONSTRAIN(ARRAYFORMULA(SUMIF(ROW(A2:A),"<="&ROW(A2:A),A2:A)-SUMIF(ROW(A2:A),"<="&ROW(A2:A),B2:B)),ARRAYFORMULA(LOOKUP(2,1/(A2:A<>""),ROW(A2:A))),1)

Answer 2

利用：

=ARRAYFORMULA(IF((A2:A<>"")+(B2:B<>""),
 MMULT(TRANSPOSE((ROW(B2:B)<=
 TRANSPOSE(ROW(B2:B)))*IF(A2:A="", -B2:B, A2:A)), 
 SIGN(IF(A2:A="", -B2:B, A2:A))^0), ))

---

或者：

=ARRAYFORMULA(IF((A2:A<>"")+(B2:B<>""),
 MMULT(TRANSPOSE((ROW(B2:B)<=TRANSPOSE(ROW(B2:B)))*
 IF(A2:A="", A2:A-B2:B, A2:A-B2:B)), 
 SIGN(IF(A2:A="", B2:B, A2:A))^0), ))

---

更新：

=ARRAYFORMULA(IF(A2:A="",,MMULT(
 TRANSPOSE((ROW(INDIRECT("2:"&MAX((A2:A<>"")*ROW(A2:A))))<=
 TRANSPOSE( ROW(INDIRECT("2:"&MAX((A2:A<>"")*ROW(A2:A))))))*
 (INDIRECT("C2:C"&MAX((A2:A<>"")*ROW(A2:A)))-
  INDIRECT("D2:D"&MAX((A2:A<>"")*ROW(A2:A))))), 
 SEQUENCE(MAX((A2:A<>"")*ROW(A2:A))-1)^0)))

Answer 3

多谢你们。 我尝试了@player0 方法并得到一个关于数组变大的错误。 出于某种原因，@TheMaster 版本卡在了进度条上。 无论如何在谷歌帮助论坛上找到了这个

=ArrayFormula(if(len(A4:A),(SUMIF(ROW(D4:D),"<="&ROW(D4:D),D4:D)+SUMIF(ROW(C4:C),"<="&ROW(C4:C),C4:C)),))

并且似乎有效（我现在在 A4:A 中有一个约会）。 但是，如果您发现任何潜在问题，请告诉我

Answer 4

更新：我看到我从@MattKing 改编的答案与@TheMaster 早期的答案非常相似，只是我们如何强制arrayformula 循环通过单元格的一种变化。

答：除了player0的解决方案，我发现了一个相关的问题（其中player0也有答案）。 并改编了@MattKing 的公式答案。 在 C1 中尝试以下操作。

={"Total";
ARRAYFORMULA(SUMIF(SEQUENCE(ROWS(A2:A),1),"<="&SEQUENCE(ROWS(A2:A),1,1,1),A2:A) -
             SUMIF(SEQUENCE(ROWS(B2:B),1),"<="&SEQUENCE(ROWS(B2:B),1,1,1),B2:B) )}

由于它最初设计为对多列求和，因此对于您的单列实现，我不确定我是否已尽可能地减少它。