用户表单 VBA Excel - Function 匹配

Question

我试图通过 VBA 代码在 Excel 中制作一个简单的用户表单。
主 function 查找一个数字并显示与其关联的值。
例如：
如果我的输入是 1 (TextBox)，那么它应该找到这个：Worksheet "db", Cell(1, 2)
这是我现在花在这个上的第二天，它仍然无法正常工作。 我想问题出在 Range 值上。

我的代码：

Option Explicit
    
Private Sub CommandButton1_Click()

    Dim RecordRow As Long
    Dim RecordRange As Range
    
    On Error Resume Next
    
    RecordRow = Application.Match(CLng(TextBox1.Value), Sheets("db").Range("B:B"), 0)
    
    Set RecordRange = Sheets("db").Range("B:G").Cells(1, 1).Offset(RecordRow - 1, 0)
    TextBox2.Value = RecordRange(1, 1).Offset(0, 1).Value
    TextBox3.Value = RecordRange(1, 1).Offset(0, 2).Value
    TextBox4.Value = RecordRange(1, 1).Offset(0, 3).Value
    TextBox5.Value = RecordRange(1, 1).Offset(0, 4).Value
        
End Sub

请你支持我好吗？

Answer 1

如果未找到匹配项Application.Match未通过运行时错误，则返回错误值。 因此，删除 OERN，将匹配返回到 Variant 并测试IsError

Private Sub CommandButton1_Click()
    Dim RecordRow As Variant

    RecordRow = Application.Match(CLng(TextBox1.Value), Sheets("db").Range("B:B"), 0)
    If Not IsError(RecordRow) Then
        With Sheets("db").Cells(RecordRow, 2)
            TextBox2.Value = .Offset(0, 1).Value
            TextBox3.Value = .Offset(0, 2).Value
            TextBox4.Value = .Offset(0, 3).Value
            TextBox5.Value = .Offset(0, 4).Value
        End With
    End If
End Sub