![](/img/trans.png)
[英]how to dynamically set Notify Filter for file system watcher in VB.NET
[英]printing png file with file system watcher vb.net
我正在尝试打印一个新创建的 png 文件。 我正在使用文件系统观察程序在创建文件并获取它的路径时做出反应。
Private Sub FileSystemWatcher1_Created(sender As Object, e As FileSystemEventArgs) Handles FileSystemWatcher1.Created
Dim MyFile As String = e.FullPath.ToString
Try
AddHandler PrintDocument1.PrintPage, AddressOf Me.PrintImage
PrintDocument1.Print()
Catch ex As Exception
MsgBox(ex, MsgBoxStyle.Critical, "Error during Print")
End Try
End Sub
但是当我想打印它时,我不知道从 MSDN 到代码的路径如何直接与此代码 Me.PrintImage 和 Me.PrintImage(MyFile) 返回错误
WithEvents PrintDocument1 As New PrintDocument
Private Sub PrintImage(ByVal sender As Object, ByVal ppea As PrintPageEventArgs, MyFile As String)
ppea.Graphics.DrawImage(Image.FromFile(MyFile), ppea.Graphics.VisibleClipBounds)
ppea.HasMorePages = False
End Sub
我怎样才能将我的文件定向到此打印服务? 我发现的代码基于文件的 static 路径,并且不在文件系统观察程序中,我似乎找不到将它们联系在一起的方法。 请帮忙!
请考虑以下几点:
Private Sub PrintImage(ByVal sender As Object, ByVal ppea As PrintPageEventArgs, MyFile As String)
MyFile
:Public Class Form1
Private MyFile As String
End Class
现在您可以在FileSystemWatcher1_Created
事件中分配它的值,并在PrintImage
事件中读取该值。 阅读更多: 如何:控制变量的 Scope (Visual Basic)
Public Class Form1
Private MyFile As String
Private PrintDocument1 As PrintDocument
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
PrintDocument1 = New PrintDocument
AddHandler PrintDocument1.PrintPage, AddressOf PrintImage
End Sub
Private Sub PrintImage(sender As Object, e As PrintPageEventArgs)
'...
End Sub
End Class
或者只是像在FileSystemWatcher1_Created
事件中一样使用WithEvents 和 Handles子句。
Public Class Form1
Private MyFile As String
Private WithEvents PrintDocument1 As PrintDocument
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
PrintDocument1 = New PrintDocument
End Sub
Private Sub PrintImage(sender As Object, e As PrintPageEventArgs) Handles PrintDocument1.PrintPage
'...
End Sub
End Class
或者使用设计器添加PrintDocument
组件的实例并订阅它的事件。 就像FileSystemWatcher
组件一样。
把它们放在一起,你应该得到类似的东西:
Public Class Form1
Private MyFile As String
Private WithEvents PrintDocument1 As PrintDocument
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
PrintDocument1 = New PrintDocument
End Sub
Private Sub FileSystemWatcher1_Created(sender As Object, e As FileSystemEventArgs) Handles FileSystemWatcher1.Created
MyFile = e.FullPath
PrintDocument1.Print()
End Sub
Private Sub PrintImage(sender As Object, e As PrintPageEventArgs) Handles PrintDocument1.PrintPage
If Not File.Exists(MyFile) Then
Return
End If
Try
Using bmp = New Bitmap(New MemoryStream(File.ReadAllBytes(MyFile)))
e.Graphics.DrawImage(bmp, e.Graphics.VisibleClipBounds)
End Using
Catch ex As ArgumentException
Console.WriteLine("Not Image!")
Catch ex As Exception
Console.WriteLine(ex.Message)
End Try
End Sub
Protected Overrides Sub OnFormClosed(e As FormClosedEventArgs)
MyBase.OnFormClosed(e)
PrintDocument1.Dispose()
End Sub
End Class
恕我直言,更好的方法是将创建的文件收集到一个列表中,并将它们作为一个打印作业发送到打印机。 例如,当您在FileSystemWatcher.Path
中粘贴多个文件时很有用。 为每个文件引发FileSystemWatcher.Created
事件,并且为每个文件调用前面代码中的PrintDocument.Print
方法。 我们可以将打印调用减少到只有一个来完成相同的任务。
下面的代码是一个快速的 Lambda-Expression-Way 示例。
Imports System.IO
Imports System.Windows.Forms
Imports System.Drawing.Printing
Imports System.Collections.Generic
Public Class Form1
Private ReadOnly watcher As FileSystemWatcher
Private ReadOnly timer As Timer 'System.Windows.Forms.Timer
Private ReadOnly printDoc As PrintDocument
Private MyFiles As Queue(Of String)
Sub New()
InitializeComponent()
MyFiles = New Queue(Of String)
watcher = New FileSystemWatcher With {
.Path = "PathToWatch",
.EnableRaisingEvents = True
}
AddHandler watcher.Created,
Sub(s, e)
If Not MyFiles.Contains(e.FullPath) Then
MyFiles.Enqueue(e.FullPath)
Invoke(Sub() timer.Start())
End If
End Sub
timer = New Timer With {.Interval = 1000}
AddHandler timer.Tick,
Sub(s, e)
timer.Stop()
printDoc.Print()
End Sub
printDoc = New PrintDocument
AddHandler printDoc.PrintPage,
Sub(s, e)
Dim imgFile = MyFiles.Dequeue
If Not File.Exists(imgFile) Then
Return
End If
Try
Using bmp = New Bitmap(New MemoryStream(File.ReadAllBytes(imgFile)))
e.Graphics.DrawImage(bmp, e.Graphics.VisibleClipBounds)
End Using
Catch ex As ArgumentException
Console.WriteLine("Not Image!")
Catch ex As Exception
Console.WriteLine(ex.Message)
End Try
e.HasMorePages = MyFiles.Count > 0
End Sub
End Sub
Protected Overrides Sub OnFormClosed(e As FormClosedEventArgs)
MyBase.OnFormClosed(e)
watcher.Dispose()
timer.Dispose()
printDoc.Dispose()
End Sub
End Class
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.