Excel：如何计算满足多个条件的不同值的数量 - 单个单元格？

Question

客户编号	案号	地址	物理文件	电子档案	如果有的话？
10001	1000101	阿迪1	不	不	0
10001	1000102	||	不	不	0
10002	1000201	NULL			1个
10003	1000301	阿迪3	是的	是的	1个
10004	1000401	阿迪4	不	不	0
10004	1000402	||	是的	不	1个
10004	1000403	||	不	不	0
10005	1000501	阿迪5	不	是的	1个
10006	1000601	阿迪6	不	不	0

我有一张 excel 的大表，无论出于何种意图和目的，它看起来都像这个例子 ^^

“如果有的话？” 列有这个公式： =IF(AND('Physical Files'="No", 'Electronic Files'="No"),0,1)

我正在计算没有物理或电子文件的客户数量。 每个客户都有一个不同的客户编号，但有些客户会多次出现多个问题。 如果文件上有客户地址，则会注明是否有物理和/或电子文件。 如果没有地址，物理/电子列留空。

不同的客户端#s	文件？
10001	0
10002	1个
10003	1个
10004	1个
10005	1个
10006	0

现在我使用=UNIQUE()生成了不同客户端#s 的列表。 在相邻的列中，我有这个公式： =SUM(FILTER(M2:M10, H2:H10=O2)) --> Column M = "If any?" 示例表中的 H 列 =“客户编号”，O 列 =“不同的客户#s”。

从那以后，我在“文件？”时使用了 COUNTIF。 Column = 0——结果是 2，这是正确的，但我试图找到一种方法来获得该结果，而不必列出不同的客户编号。 有没有办法在单个单元格中执行此操作？

Answer 1

您可以在单元格H2中尝试以下操作：

=HSTACK(UNIQUE(A2:A10), SUMIFS(F2:F10,A2:A10,UNIQUE(A2:A10)))

这是 output：

如果您的 excel 版本中没有HSTACK ，则可以使用以下命令：

=CHOOSE({1,2}, UNIQUE(A2:A10), SUMIFS(F2:F10,A2:A10,UNIQUE(A2:A10)))

Answer 2

=SUMPRODUCT(        
            (MMULT(               
                   COUNTIFS(A2:A10,A2:A10,D2:D10,{"Yes",""})+COUNTIFS(A2:A10,A2:A10,E2:E10,{"Yes",""}),
                   {1;1})
                         >0)
             /COUNTIF(A2:A10,A2:A10)
             )

MMULT 计算哪个 ID 对 D 或 E 列中Yes或""的一个或多个匹配项除以 ID 的计数。 因此，如果您对这些求和，则每个 ID 的总和为 1，因此公式的结果是满足给定条件的唯一 ID 的计数。

编辑：我读到它是相反的； 然后从总的唯一计数中减去前一个：

=SUM(1/COUNTIF(A2:A10,A2:A10))-
     SUMPRODUCT(
                (MMULT(
     
                       COUNTIFS(A2:A10,A2:A10,D2:D10,{"Yes",""})+COUNTIFS(A2:A10,A2:A10,E2:E10,{"Yes",""}),
                       {1;1})
                             >0)
       
                /COUNTIF(A2:A10,A2:A10)
                )