计算pivot表计算字段中两个日期之间的平均持续时间

Question

我想在 pivot 表中计算每个项目的两次更改（日期）之间的平均持续时间。

这是包含数据的工作表：

物品	更改于
项目3	2023-01-25
项目2	2022-10-12
项目3	2022-08-15
项目3	2022-03-06
项目2	2021-12-18
项目1	2021-06-28

我需要一个 pivot 表来计算每个项目的平均持续时间，如下所示：

物品	平均。 两次更改之间的时间
项目1	没有数据
项目2	298
项目3	162.5

Answer 1

尝试：

=INDEX(LAMBDA(a, b, QUERY(QUERY({a, IFNA(VLOOKUP(a&"×"&
 COUNTIFS(a, a, ROW(a), "<="&ROW(a))-1, {a&"×"&
 COUNTIFS(a, a, ROW(a), "<="&ROW(a)), b}, 2, )-b)}, 
 "select Col1,avg(Col2) where Col2 is not null group by Col1"), 
 "offset 1", ))(A:A, B:B))

---

=INDEX(LAMBDA(a, b, {SORT(UNIQUE(FILTER(a, a<>""))), 
 IFNA(VLOOKUP(SORT(UNIQUE(FILTER(a, a<>""))), 
 QUERY(QUERY({a, IFNA(VLOOKUP(a&"×"&
 COUNTIFS(a, a, ROW(a), "<="&ROW(a))-1, {a&"×"&
 COUNTIFS(a, a, ROW(a), "<="&ROW(a)), b}, 2, )-b)}, 
 "select Col1,avg(Col2) where Col2 is not null group by Col1"), 
 "offset 1", ), 2, ), "no data")})(A:A, B:B))

=INDEX(LAMBDA(a; b; {SORT(UNIQUE(FILTER(a; a<>"")))\ 
 IFNA(VLOOKUP(SORT(UNIQUE(FILTER(a; a<>""))); 
 QUERY(QUERY({a\ IFNA(VLOOKUP(a&"×"&
 COUNTIFS(a; a; ROW(a); "<="&ROW(a))-1; {a&"×"&
 COUNTIFS(a; a; ROW(a); "<="&ROW(a))\ b}; 2; )-b)}; 
 "select Col1,avg(Col2) where Col2 is not null group by Col1"); 
 "offset 1"; ); 2; ); "no data")})(A:A; B:B))