如何使用XSLT显示经过XSD验证的XML

Question

我已经为此奋斗了一段时间，还没有找到明确的答案。

据我了解，我可以将数据存储在XML文件中，使用XSD对其进行验证，然后使用XSLT整齐地显示数据。

但是，在尝试执行XPath查询以选择希望在XSLT中显示的数据时遇到了问题。 当我使用'.//'或'*'之类的通用选择器时，我会得到预期的结果。 但是，当我尝试使用更具体的选择器时，例如：'root / responses'或其任何其他变体，没有任何结果。

XSD已正确验证了XML文件，因此我想我的数据至少在某种程度上是正确的。 当我删除XML文件中的XSD引用，从而有效地删除了数据验证时，我的XPath查询突然起作用了！ 有什么我想念的吗？ 我尝试将名称空间引用添加到XSLT，但无济于事。

我在下面介绍了XSD，示例XL和示例XSLT。 任何帮助或提示，将不胜感激！

定义结构的XSD如下。 该XSD描述了一个简单的文档，该文档嵌套了三个元素并施加了约束。 响应代码的代码必须唯一。

<?xml version="1.0" encoding="utf-8"?>
    <xs:schema id="uitext"
        targetNamespace="http://foo.bar/responsecode.xsd"
        elementFormDefault="qualified"
        xmlns:responsecodes="http://foo.bar/responsecode.xsd"
        xmlns:xs="http://www.w3.org/2001/XMLSchema">

        <xs:element name="root" type="responsecodes:rootType">
            <xs:key name="responseCode">
                <xs:selector xpath="responsecodes:responses/responsecodes:response">
                    <xs:annotation>
                        <xs:documentation>All defined responsecodes</xs:documentation>
                    </xs:annotation>
                </xs:selector>
                <xs:field xpath="@code">
                    <xs:annotation>
                        <xs:documentation>Unique responsecode</xs:documentation>
                    </xs:annotation>
                </xs:field>
            </xs:key>
        </xs:element>

        <xs:complexType name="rootType">
            <xs:sequence>
                <xs:element name="responses" minOccurs="1" maxOccurs="1" type="responsecodes:responseList">
                    <xs:annotation>
                        <xs:documentation>Defined responsecodes</xs:documentation>
                    </xs:annotation>
                </xs:element>
            </xs:sequence>
        </xs:complexType>

        <xs:complexType name="responseList">
            <xs:sequence>
                <xs:element name="response" minOccurs="0" maxOccurs="unbounded" type="responsecodes:response"/>
            </xs:sequence>
        </xs:complexType>

        <xs:complexType name="response">
            <xs:sequence>
                <xs:element name="description" type="xs:string" minOccurs="0" maxOccurs="1">
                    <xs:annotation>
                        <xs:documentation>
                            Explains the use of the responsecode.
                        </xs:documentation>
                    </xs:annotation>
                </xs:element>
            </xs:sequence>
            <xs:attribute name="code" type="xs:string" use="required">
                <xs:annotation>
                    <xs:documentation>Unique code representing the response provided.</xs:documentation>
                </xs:annotation>
            </xs:attribute>
        </xs:complexType>
    </xs:schema>

XML文档示例可以如下所示：

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="responsecode.xsl"?>
<root xmlns="http://foo.bar/responsecode.xsd"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xsi:schemaLocation="http://foo.bar/responsecode.xsd responsecode.xsd">
    <responses>
        <response code="firstCode">
            <description>Explanation of first code</description>
        </response>
        <response code="secondCode">
            <description>Explanation of second code</description>
        </response>
        <response code="thirdCode">
            <description>Explanation of third code.</description>
        </response>
    </responses>
</root>

XML文件中引用的测试XSLT文档如下。 （这将以类似于VS2008枚举定义的格式显示上述代码，但不包括）

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <html><body><h2>Responses</h2>

                <xsl:for-each select="root/responses/response">
                    <xsl:choose>
                        <xsl:when test="description != ''">
                            <br/>'''&lt;description&gt;
                            <br/>'''<xsl:value-of select="description" />
                            <br/>'''&lt;/description&gt;
                        </xsl:when>
                    </xsl:choose>
                    <br/>
                    <xsl:value-of select="@code" />

                </xsl:for-each>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

Answer 1

一个简单的问题：您的XML元素位于XSLT不知道的名称空间中。

<root xmlns="http://foo.bar/responsecode.xsd">
  <responses>
    <!-- ... -->
  </responses>
</root>

将您的<root>和所有后代元素放入"http://foo.bar/responsecode.xsd"命名空间。

像这样更改您的XSL：

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:foo="http://foo.bar/responsecode.xsd"
  exclude-result-prefixes="foo"
>
  <xsl:template match="/">
    <html>
      <body>
        <h2>Responses</h2>
        <xsl:for-each select="foo:root/foo:responses/foo:response">
          <!-- ... -->
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

请注意如何声明名称空间并为其指定前缀。 以后，使用该前缀引用该名称空间中的所有节点。 exclude-result-prefixes用于确保名称空间不会不必要地出现在输出中。

Answer 2

当然，一旦您发布问题，您就会自己找到答案！

事实证明，名称空间引用中肯定存在拼写错误。 仔细检查此帖子后：

xslt-transform-xml-with-namespaces

基本上，这是相同的问题。 （我在发布之前进行了搜索。...诚实！），我尝试再次添加名称空间引用，但这一次它运行得很顺利！

我将名称空间映射到前缀“ nsm”（NameSpaceMapping）并贴上标签！

<?xml version="1.0" encoding="iso-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:nsm="http://foo.bar/responsecode.xsd">
    <xsl:template match="/">
        <html><body><h2>Responses</h2>

                        <xsl:for-each select="nsm:root/nsm:responses/nsm:response">
                                <xsl:choose>
                                        <xsl:when test="nsm:description != ''">
                                                <br/>'''&lt;description&gt;
                                                <br/>'''<xsl:value-of select="nsm:description" />
                                                <br/>'''&lt;/description&gt;
                                        </xsl:when>
                                </xsl:choose>
                                <br/>
                                <xsl:value-of select="@code" />

                        </xsl:for-each>
                </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

Answer 3

这是一个名称空间问题。 您必须为http://foo.bar/responsecode.xsd添加名称空间声明，并使用该名称空间引用元素。 更多信息可以在这里找到。

因此，基本上，您将需要以下内容：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:test="http://foo.bar/responsecode.xsd">
  <xsl:template match="/">
    <html>
      <body>
        <h2>Responses</h2>

        <xsl:for-each select="test:root/test:responses/test:response">
          <xsl:choose>
            <xsl:when test="test:description != ''">
              <br/>'''&lt;description&gt;
              <br/>'''<xsl:value-of select="test:description" />
              <br/>'''&lt;/description&gt;
            </xsl:when>
          </xsl:choose>
          <br/>
          <xsl:value-of select="@code" />

        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>

注意xsl:stylesheet的属性中的“ xmlns：test”。 我对此进行了测试，它可以正常工作。

如何使用XSLT显示经过XSD验证的XML

问题描述

3 个解决方案

解决方案1
9 2009-11-18 15:49:03

解决方案2
7 已采纳 2009-11-18 15:47:56

解决方案3
4 2009-11-18 15:48:13

如何使用XSLT显示经过XSD验证的XML

问题描述

3 个解决方案

解决方案1 9 2009-11-18 15:49:03

解决方案2 7 已采纳 2009-11-18 15:47:56

解决方案3 4 2009-11-18 15:48:13

解决方案1
9 2009-11-18 15:49:03

解决方案2
7 已采纳 2009-11-18 15:47:56

解决方案3
4 2009-11-18 15:48:13