如何在Delphi中使用Default（T）测试泛型类型变量是否相等？

Question

我正在尝试编写如下所示的通用缓存属性访问器，但在尝试检查存储变量是否已包含值时遇到编译器错误：

function TMyClass.GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
begin
  if ADataValue = Default(T) then // <-- compiler error on this line
    ADataValue := ARetriever();
  Result := ADataValue;
end;

我得到的错误是“E2015运算符不适用于此操作数类型”。

我是否必须对T进行约束才能使其工作？ 帮助文件说Default()将接受除泛型类型之外的任何内容。 在我的情况下，我主要处理简单类型，如String ， Integer和TDateTime 。

或者是否有其他库函数来执行此特定检查？

我正在使用Delphi 2009以防万一。

---

PS：以防万一我从代码中不清楚我正在尝试做什么：在我的情况下，由于各种原因确定实际属性值可能需要一段时间，有时甚至根本不需要它们。 但是在正面，值是常量，所以我只想调用第一次访问该属性时确定实际值的代码，然后将值存储在类字段中，下次访问该属性时返回缓存值直。 这是我希望能够使用该代码的示例：

type
  TMyClass = class
  private
    FSomeProp: String;
    function GetSomeProp: String;

    function GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
  public
    property SomeProp read GetSomeProp;
  end;

function GetSomeProp: String;
begin
  Result := GetProp<String>(FSomeProp,
                            function: String
                            begin
                              Result := SomeSlowOrExpensiveCalculation;
                            end);
end;

（显然，这不仅仅是一个属性）

Answer 1

在Binis的评论中提示并在Generics.Collections中稍微挖掘一下之后，我想出了以下内容，它看起来像我想要的那样工作：

function TMyClass.GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
var
  lComparer: IEqualityComparer<T>;
begin
  lComparer := TEqualityComparer<T>.Default;
  if lComparer.Equals(ADataValue, Default(T)) then
    ADataValue := ARetriever();
  Result := ADataValue;
end;

Answer 2

据我所知，看起来你想要做一些memoize功能。 如果是这种情况，请阅读本文

http://blogs.teamb.com/craigstuntz/2008/10/01/37839/

Answer 3

问题不是Default函数，而是等于operator = 。

您可以将T约束为IEquatable并使用如下的Equals方法：

TMyClass = class
  function GetProp<T : IEquatable<T>>(var ADataValue: T; const ARetriever: 
end;
...
function TMyClass.GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
begin  
if ADataValue.Equals (Default(T)) then
  ADataValue := ARetriever();  
Result := ADataValue;
end;