如何在目录中生成 Perl 模块或脚本的 HTML 摘要？

Question

是否有可用的工具可以在目录树中生成 perl 模块或脚本的 HTML 摘要列表？

给定的

 =head1 NAME

 wibble.pl - does wibble actions

我想看到类似的东西

<a href="docsforwibble">wibble.pl</a> - does wibble actions
<a href="docsforwobble">wobble.pl</a> - does wobble actions

Answer 1

pod2html --recurse --podpath <dirname>

见perldoc pod2html

Answer 2

使用Pod::Parser发行版中的Pod::Find很容易找到一个。

下面的脚本为它可以在我的site/lib/CGI下找到的任何内容创建一个基本的索引文件。 它的意思是作为示范。 使用pod2html可能会更好，但此脚本可能仍然有用。

#!/usr/bin/perl

use strict; use warnings;
use autodie;

use File::Spec::Functions qw( canonpath );
use HTML::Template;
use Pod::Find qw(pod_find simplify_name);
use Pod::Select;

my $mod_top = canonpath 'c:/opt/perl/site/lib/CGI';
my $html_top = 'c:/opt/perl/html/site/lib/CGI';

my %pods = pod_find($mod_top);
my @pods;

for my $pod ( sort keys %pods ) {
    (my $link = $pod) =~ s/^\Q$mod_top//;
    $link =~ s/\.\w+\z//;
    $link = "file:///${html_top}${link}.html";

    my $name;
    {
        local *STDOUT;
        open STDOUT, '>', \$name;
        podselect({-sections => [ 'NAME' ] }, $pod);
    }
    $name = '' unless defined $name;
    $name =~ s/^=head1\s+NAME\s+//;
    $name =~ s/\s+\z//;

    push @pods, {
        POD => $pods{$pod},
        NAME => $name,
        LINK => $link,
    };
}

my $tmpl = HTML::Template->new(scalarref => \ <<EO_TMPL
<!DOCTYPE HTML>
<html>
<head><title>Index of Perl Modules</title></head>
<body>
<h1><TMPL_VAR CATEGORY></h1>
<dl>
<TMPL_LOOP PODS>
<dt><a href="<TMPL_VAR LINK>"><TMPL_VAR POD></a></dt>
<dd><TMPL_VAR NAME></dd>
</TMPL_LOOP>
</ul>
</body>
</html>
EO_TMPL
);

$tmpl->param(
    CATEGORY => 'CGI',
    PODS => \@pods,
);
$tmpl->output(print_to => \*STDOUT);

如何在目录中生成 Perl 模块或脚本的 HTML 摘要？

问题描述

2 个解决方案

解决方案1
2 2010-03-17 17:50:40

解决方案2
1 已采纳 2010-03-17 17:50:11

如何在目录中生成 Perl 模块或脚本的 HTML 摘要？

问题描述

2 个解决方案

解决方案1 2 2010-03-17 17:50:40

解决方案2 1 已采纳 2010-03-17 17:50:11

解决方案1
2 2010-03-17 17:50:40

解决方案2
1 已采纳 2010-03-17 17:50:11