如何判断Perl代码中的一组parens是作为分组parens还是组成一个列表？

Question

在perl中，括号用于覆盖优先级（如在大多数编程语言中）以及用于创建列表。 如何判断一对特定的parens是被视为分组构造还是单元素列表？

例如，我很确定这是一个标量而不是单元素列表： (1 + 1)
但是更复杂的表达呢？ 有简单的说法吗？

Answer 1

这里有三个关键原则：

语境是王道。 您的示例(1 + 1)的评估取决于上下文。

$x = (1 + 1); # Scalar context. $x will equal 2. Parentheses do nothing here.
@y = (1 + 1); # List context. @y will contain one element: (2).
              # Parens do nothing (see below), aside from following 
              # syntax conventions.

在标量上下文中，没有列表这样的东西 。 要查看此内容，请尝试将显示为列表的内容分配给标量变量。 考虑这一点的方法是关注逗号运算符的行为：在标量上下文中，它计算其左参数，抛出该值，然后计算其右参数，并返回该值。 在列表上下文中，逗号运算符将两个参数都插入到列表中。

@arr  = (12, 34, 56); # Right side returns a list.

$x    = (12, 34, 56); # Right side returns 56. Also, we get warnings
                      # about 12 and 34 being used in void context.

$x = (@arr, 7);       # Right side returns 7. And we get a warning
                      # about using an array in a void context.

括号不会创建列表 。 逗号运算符创建列表（假设我们在列表上下文中）。 在Perl代码中键入列表时，出于优先级原因需要使用括号 - 而不是出于列表创建原因。 几个例子：

• 括号没有效果：我们在标量上下文中评估数组，因此右侧返回数组大小。

   $x = (@arr); 

• 创建包含一个元素的列表不需要括号。

   @arr = 33; # Works fine, with @arr equal to (33). 

• 但是出于优先原因，需要多个项目的括号。

   @arr = 12, 34, 56; # @arr equals (12). And we get warnings about using # 34 and 56 in void context. 

Answer 2

1. 语境。
2. 括号没有您认为他们在创建列表时所具有的角色。

例子：

$x = 1 + 1;   # $x is 2.
$x = (1 + 1); # $x is 2.
@x = 1 + 1;   # @x is (2).
@x = (1 + 1); # @x is (2).

$x = (1 + 1, 1 + 2); # $x is 3.
@x = (1 + 1, 1 + 2); # @x is (2, 3).

粗略地说，在列表上下文中，逗号运算符分隔列表的项目; 在标量上下文中，逗号运算符是C“串行逗号”，它评估其左侧和右侧，并返回右侧的值。 在标量上下文中，括号将表达式组覆盖以覆盖操作的顺序，并且在列表上下文中，括号表示......完全相同的事情。 它们与分配数组相关的原因是：

# Comma has precedence below assignment. 
# @a is assigned (1), 2 and 3 are discarded.
@a = 1, 2, 3; 

# @a is (1, 2, 3).
@a = (1, 2, 3);

至于你的问题“它是标量还是单元素列表”，由于上下文的原因，单独询问表达式并不是一个有意义的问题。 在列表上下文中，一切都是列表; 在标量语境中，什么都没有。

推荐阅读： perlop ， perldata ， 编程Perl 。