如何在Flex中创建文本步进控件？

Question

我在Flex 3中需要一个类似于NumericStepper的控件，但是它可以显示任意字符串。 是否存在此控件？ 如果没有，您对创建它有什么建议，或者您会推荐哪些参考？

为了方便起见，我将其称为TextStepper。 我希望这是一种紧凑的方式来显示字符串选择列表，用户可以通过单击上/下按钮来循环选择这些字符串。 紧凑表示控件没有下拉或弹出窗口：更改所选索引的唯一方法是单击上/下按钮（这将更新文本输入值）。 值循环意味着我真的想将基础dataProvider视为循环缓冲区。 因此，上/下单击以模数方式修改selectedIndex。

Answer 1

这个想法是使用valueFormatFunction ：

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
               xmlns:s="library://ns.adobe.com/flex/spark" 
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600" xmlns:local="*">

    <local:StringStepper horizontalCenter="0" verticalCenter="0" width="200">
        <local:dataProvider>
            <s:ArrayCollection>
                <fx:String>Hello!</fx:String>
                <fx:String>I love you.</fx:String>
                <fx:String>Won't you tell me your name?</fx:String>
            </s:ArrayCollection>
        </local:dataProvider>
    </local:StringStepper>

</s:Application>

StringStepper的来源：

package
{
import mx.collections.ArrayCollection;
import mx.events.CollectionEvent;

import spark.components.NumericStepper;

public class StringStepper extends NumericStepper
{
    public function StringStepper()
    {
        enabled = false;
        valueFormatFunction = defaultValueFormatFunction;
        valueParseFunction = defaultValueParseFunction;
    }

    private var _dataProvider:ArrayCollection;

    public function get dataProvider():ArrayCollection
    {
        return _dataProvider;
    }

    public function set dataProvider(value:ArrayCollection):void
    {
        if (_dataProvider == value)
            return;

        if (_dataProvider)
            _dataProvider.removeEventListener(CollectionEvent.COLLECTION_CHANGE,
                dataProvider_collectionChangeHandler);

        _dataProvider = value;
        commitDataProvider();

        if (_dataProvider)
            _dataProvider.addEventListener(CollectionEvent.COLLECTION_CHANGE,
                dataProvider_collectionChangeHandler);
    }

    /**
     * Same event as for <code>value</code>.
     */
    [Bindable("valueCommit")]
    public function get selectedItem():Object
    {
        return _dataProvider && value <= _dataProvider.length - 1 ? _dataProvider[value] : null; 
    }

    public function set selectedItem(value:Object):void
    {
        if (!_dataProvider)
            return;

        value = _dataProvider.getItemIndex(value);
    }

    private function defaultValueFormatFunction(value:Number):String
    {
        return _dataProvider && value <= _dataProvider.length - 1 ? _dataProvider[value] : String(value);
    }

    private function defaultValueParseFunction(value:String):Number
    {
        if (!_dataProvider)
            return 0;

        var n:int = _dataProvider.length;
        for (var i:int = 0; i < n; i++)
        {
            var string:String = _dataProvider[i];
            if (string == value)
                return i;
        }
        return 0;
    }

    private function commitDataProvider():void
    {
        if (!_dataProvider)
        {
            minimum = 0;
            maximum = 0;
            enabled = false;
            return;
        }

        enabled = true;
        minimum = 0;
        maximum = _dataProvider.length - 1;
    }

    private function dataProvider_collectionChangeHandler(event:CollectionEvent):void
    {
        commitDataProvider();
    }

}
}

Answer 2

我通过将TextInput覆盖在NumericStepper （绝对位置）上来创建其中一个（作为MXML组件），以便TextInput覆盖NumericStepper的输入部分。

dataProvider是字符串的ArrayCollection ，并且使用NumericStepper的值来访问ArrayCollection中的索引。

NumericStepper的change事件将TextInput的文本更改为dataProvider的索引n处的内容。 我为组件提供了一个editable属性，该属性将TextInput设置为editable，并将新字符串插入当前索引处的dataProvider中。