序言：从命题公式中获得唯一原子

Question

我可以轻松地编写一个谓词以从Prolog中的给定列表中获取唯一元素，例如

no_doubles( [], [] ).
no_doubles( [H|T], F ) :-
 member( H, T ),
 no_doubles( T, F ).
no_doubles( [H|T], [H|F] ) :-
 \+ member( H, T ),
 no_doubles( T, F ).

但是，除了正常列表以外，您如何才能做同样的事情，即不是[a，b，c ...]之类的事情？ 因此，在我的情况下，我想为命题公式提取唯一原子，例如unique_atoms（and（x，and（x，y），z），[x，y，z]）。 很满意。 您是否像我的no_doubles示例中那样使用递归，但是否使用了这样的公式？

任何想法都欢迎:)。 谢谢。

Answer 1

因此，您需要处理一个通用术语（即树结构），并获取其原子叶节点的列表，且不能重复。 结果列表是否必须具有特定的顺序（例如，深度从左到右）？这不重要吗？

如果您可以选择在公式中使用变量而不是原子，则可以使用（SWI-Prolog）内置term_variables/2 ，例如

?- term_variables(and(X, and(X, Y), Z), Vars).
Vars = [X, Y, Z].

否则，您必须采用类似于以下的解决方案：

term_atoms(Term, AtomSet) :-
    term_to_atomlist(Term, AtomList),
    list_to_set(AtomList, AtomSet).


term_to_atomlist(Atom, [Atom]) :-
    atom(Atom),
    !.

term_to_atomlist(Term, AtomList) :-
    compound(Term),
    Term =.. [_ | SubTerms],
    terms_to_atomlist(SubTerms, AtomList).


terms_to_atomlist([], []).

terms_to_atomlist([Term | Terms], AtomList) :-
    term_to_atomlist(Term, AtomList1),
    terms_to_atomlist(Terms, AtomList2),
    append(AtomList1, AtomList2, AtomList).

用法示例：

?- term_atoms(f(x^a1+a3*a3/a4)='P'-l, Atoms).
Atoms = [x, a1, a3, a4, 'P', l].

您可能需要扩展它以处理叶节点中的数字和变量。

Answer 2

?- setof(X, member(X,[a,b,c,a,b,c]), L).
L = [a, b, c].

?- sort([a,b,c,a,b,c], L).
L = [a, b, c].

命题公式：

get_atoms(X,[X]) :-
    atom(X).
get_atoms(and(P,Q),Atoms) :-
    get_atoms(P,Left),
    get_atoms(Q,Right),
    append(Left,Right,Atoms).

等。如有必要，使用差异列表进行优化。

unique_atoms(P,UniqueAtoms) :- get_atoms(P,Atoms), sort(Atoms,UniqueAtoms).

一种更直接的方法是使用集合 。