使用XSLT在XML元素内打印一组键值数据对
[英]Printing the set of key-value pairs of data inside a XML element using XSLT
问题描述
对于给定的XML节点，我需要获取它的键值对。 例如：
对于XML：
<root>
<detail1>
<test1> Text1 </test1>
<test2> Text2 </test2>
<test3> Text3 </test3>
</detail1>
<detail2> description 1 </detail2>
<detail3> description 2 </detail3>
</root>
我需要一个如下表（忽略最上面的元素）：
detail1 | test1 : Text1
| test2 : Text2
| test2 : Text3
|
detail2 | description 1
|
detail3 | description 2
XSLT有可能吗？ 如果有人可以给我指出一个例子或资源，那将非常有用。
5 个解决方案
解决方案1
2 已采纳 2010-11-05 12:57:01
此转换 ：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:strip-space elements="*"/>
<xsl:variable name="vBlanks" select="' '"/>
<xsl:template match="/*/*">
<xsl:value-of select="concat('
', name(), ' | ')"/>
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="/*/*/*">
<xsl:value-of select="concat(name(), ' : ')"/>
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="/*/*/*[not(position()=1)]">
<xsl:text>
</xsl:text>
<xsl:value-of select="substring($vBlanks,1,string-length(name(..))+1)"/>
<xsl:value-of select="concat('| ', name(), ' : ')"/>
<xsl:apply-templates/>
</xsl:template>
</xsl:stylesheet>
当应用于提供的XML文档时 ：
<root>
<detail1>
<test1> Text1 </test1>
<test2> Text2 </test2>
<test3> Text3 </test3>
</detail1>
<detail2> description 1 </detail2>
<detail3> description 2 </detail3>
</root>
产生想要的正确结果 ：
detail1 | test1 : Text1
| test2 : Text2
| test3 : Text3
detail2 | description 1
detail3 | description 2
解决方案2
1 2010-11-05 06:41:15
您应该查看Java中的Print XML标记名称和值 。 主要思想是name（）和text（）函数，构建格式应该相对容易
解决方案3
1 2010-11-05 06:41:49
是。 您需要for-each标记，该标记使您可以遍历XPath表达式的结果。
有关说明和用例，请参见http://www.w3schools.com/xsl/xsl_for_each.asp 。
解决方案4
1 2010-11-05 09:26:17
我喜欢使用xsl：apply-templates优于使用xsl：for-each。
编辑：将匹配子句从 *[text()] 更改为 *[count(text()) = 1]
如果您应用此转换
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
<table>
<xsl:apply-templates select="root/*"/>
</table>
</html>
</xsl:template>
<xsl:template match="*[count(text()) = 1]">
<tr>
<td>
<xsl:value-of select="name()"/>
</td>
<td>
<xsl:value-of select="."/>
</td>
</tr>
</xsl:template>
<xsl:template match="*">
<xsl:apply-templates select="*" mode="keyvalue"/>
</xsl:template>
<xsl:template match="*" mode="keyvalue">
<tr>
<xsl:choose>
<xsl:when test="position() = 1">
<td>
<xsl:value-of select="name(..)"/>
</td>
<td>
<xsl:call-template name="formatkeyvalue"/>
</td>
</xsl:when>
<xsl:otherwise>
<td></td>
<td>
<xsl:call-template name="formatkeyvalue"/>
</td>
</xsl:otherwise>
</xsl:choose>
</tr>
</xsl:template>
<xsl:template name="formatkeyvalue">
<xsl:value-of select="concat(name(), ' : ', text())"/>
</xsl:template>
</xsl:stylesheet>
输入您的信息
<html>
<table>
<tr>
<td>detail1</td>
<td>test1 : Text1 </td>
</tr>
<tr>
<td></td>
<td>test2 : Text2 </td>
</tr>
<tr>
<td></td>
<td>test3 : Text3 </td>
</tr>
<tr>
<td>detail2</td>
<td> description 1 </td>
</tr>
<tr>
<td>detail3</td>
<td> description 2 </td>
</tr>
</table>
</html>
解决方案5
1
此样式表：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/*">
<table border="1px">
<xsl:apply-templates/>
</table>
</xsl:template>
<xsl:template match="/*/*">
<tr>
<td>
<xsl:value-of select="name()"/>
</td>
<td>
<xsl:apply-templates/>
</td>
</tr>
</xsl:template>
<xsl:template match="/*/*/*">
<xsl:value-of select="concat(name(),' : ')"/>
<xsl:apply-templates/>
<xsl:if test="following-sibling::*">
<br/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
输出：
<table border="1px">
<tr>
<td>detail1</td>
<td>test1 : Text1
<br />test2 : Text2
<br />test3 : Text3
</td>
</tr>
<tr>
<td>detail2</td>
<td> description 1 </td>
</tr>
<tr>
<td>detail3</td>
<td> description 2 </td>
</tr>
</table>
反序列化为作为XML属性提供的地图键/值对（Java）
[英]Deserialising to a map key-value pairs provided as XML attributes (Java)
如何使用JDO存储键值对（datanucleus＆appengine）
[英]How to store Key-Value pairs using JDO (datanucleus & appengine)
声明:本站的技术帖子网页，遵循CC BY-SA 4.0协议，如果您需要转载，请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.