如何从oracle中的另一个存储过程调用存储过程

Question

我有一个现有的存储过程，它接受2个参数并返回一个oracle游标。 游标包含大约30到60行数据。

我想在另一个存储过程中使用上面预先存在的存储过程作为表...基本上我想调用预先存在的存储过程并查看返回的行是否包含特定值。

例如：

SP 1 = get_data_1 (returns oracle cursor)
SP 2 = get_data_2 

在get_data_2中

select count(*) from get_data_1 (pass_input_parms) A where A.ID = '12345'

从概念上讲，对我来说似乎是一件微不足道的事情，但对于oracle世界的新手，我不知道如何利用返回游标的预先存在的存储过程。

我该怎么做？

Answer 1

您不能在后续SQL语句中重用get_data_1中的REF CURSOR，因为它只是指向语句句柄的指针。 游标本身不包含任何数据。

你可以做点什么

CREATE PROCEDURE get_data_2( p_cnt OUT NUMBER )
AS
  l_rc  <<your cursor type>>;
  l_rec <<the type your cursor returns>>;
BEGIN
  get_data_1(<<parameter 1>>, <<parameter 2>>, l_rc);
  p_cnt := 0;
  LOOP
    FETCH l_rc INTO l_rec;
    EXIT WHEN l_rc%NOTFOUND;

    IF( l_rec.id = '12345' )
    THEN
      p_cnt := p_cnt + 1;
    END IF;
  END LOOP;
  CLOSE l_rc;
END;

然而，正如您可能想象的那样，这种情况往往相对较快。 鉴于此，Oracle中通常不会出现返回REF CURSOR参数的存储过程，除非您将完成的数据视图返回给客户端应用程序。 例如，如果存在共享视图，GET_DATA_1和GET_DATA_2都可以查询而不是让GET_DATA_2调用GET_DATA_1，这将简化程序。 如果GET_DATA_1是流水线表函数而不是返回REF CURSOR的过程，那么从GET_DATA_2调用GET_DATA_1会容易得多。

如果您想开始使用流水线表函数（使用SCOTT模式）

create or replace type emp_obj as object (
  empno number,
  ename varchar2(10),
  job   varchar2(9),
  mgr   number,
  hiredate date );
/

create type emp_tbl
as
table of emp_obj;
/

create function emp_pipe( p_deptno IN NUMBER )
  return emp_tbl pipelined
is
begin
  FOR x IN (SELECT * FROM emp WHERE deptno = p_deptno)
  LOOP
    PIPE ROW( emp_obj( x.empno,
                       x.ename,
                       x.job,
                       x.mgr,
                       x.hiredate ) );
  END LOOP;
END;
/

SQL> select * from table( emp_pipe( 10 ) );

     EMPNO ENAME      JOB              MGR HIREDATE
---------- ---------- --------- ---------- ---------
      7782 CLARK      MANAGER         7839 09-JUN-81
      7839 KING       PRESIDENT            17-NOV-81
      7934 MILLER     CLERK           7782 23-JAN-82

Answer 2

此时，您还可以定义一个新包并学习如何使用游标循环来处理它，它将为您提供更多的编程控制。 PL / SQL是您需要查找的内容。