使用clojure宏在reify调用中自动创建getter和setter

Question

我正在尝试使用大量（~50）getter和setter方法（一些具有不规则名称）实现一个巨大的Java接口。 我认为使用宏来减少代码量会很好。 而不是

(def data (atom {:x nil}))
(reify HugeInterface
  (getX [this] (:x @data))
  (setX [this v] (swap! data assoc :x v))) 

我希望能够写作

(def data (atom {:x nil}))
(reify HugeInterface
  (set-and-get getX setX :x))

这个set-and-get宏（或类似的东西）可能吗？ 我无法让它发挥作用。

Answer 1

（更新了第二种方法 - 见下面第二条横向规则 - 以及一些解释性说明：第一条。）

---

我想知道这是否可能是朝着正确方向迈出的一步：

(defmacro reify-from-maps [iface implicits-map emit-map & ms]
  `(reify ~iface
     ~@(apply concat
         (for [[mname & args :as m] ms]
           (if-let [emit ((keyword mname) emit-map)]
             (apply emit implicits-map args)
             [m])))))

(def emit-atom-g&ss
  {:set-and-get (fn [implicits-map gname sname k]
                  [`(~gname [~'this] (~k @~(:atom-name implicits-map)))
                   `(~sname [~'this ~'v]
                      (swap! ~(:atom-name implicits-map) assoc ~k ~'v))])})

(defmacro atom-bean [iface a & ms]
  `(reify-from-maps ~iface {:atom-name ~a} ~emit-atom-g&ss ~@ms))

NB。 atom-bean宏将emit-atom-g&ss的实际编译时值传递给reify-from-maps 。 一旦编译了特定的atom-bean表单，对emit-atom-g&ss任何后续更改都不会影响所创建对象的行为。

REPL的示例宏展开（为清晰起见，添加了一些换行符和缩进）：

user> (-> '(atom-bean HugeInterface data
             (set-and-get setX getX :x))
          macroexpand-1
          macroexpand-1)
(clojure.core/reify HugeInterface
  (setX [this] (:x (clojure.core/deref data)))
  (getX [this v] (clojure.core/swap! data clojure.core/assoc :x v)))

两个macroexpand-1是必需的，因为atom-bean是一个宏，它扩展到另一个宏调用。 macroexpand不会是特别有用，因为它会扩大这种一路调用reify* ，实现细节背后的reify 。

这里的想法是你可以提供像emit-atom-g&ss一样的emit-map ，由关键字键控，其名称（符号形式）将在reify-from-maps调用中触发魔术方法生成。 魔术由存储为给定emit-map中的函数的函数执行; 函数的参数是一个“implicits”的映射（基本上是任何和所有信息都应该是reify-from-maps形式的所有方法定义都可以访问，比如这个特殊情况下的原子名称）后面跟着哪个参数在reify-from-maps的reify-from-maps中给出了“魔术方法说明符”。 如上所述， reify-from-maps需要查看实际的关键字 - >功能图，而不是其符号名称; 因此，它只适用于文字地图，其他宏内或借助eval 。

正常的方法定义仍然可以包含在内，并且将被视为常规的reify形式，前提是匹配其名称的键不会出现在emit-map 。 所述发送功能必须在由期望的格式返回的方法定义seqables（例如载体） reify ：以这种方式，与多个方法定义的情况下返回一个“魔术方法指定符”是相对简单的。 如果iface参数用替换ifaces和~iface用~@ifaces在reify-from-maps的身体，多个接口可以为实现中指定。

---

这是另一种方法，可能更容易推理：

(defn compile-atom-bean-converter [ifaces get-set-map]
  (eval
   (let [asym (gensym)]
     `(fn [~asym]
        (reify ~@ifaces
          ~@(apply concat
              (for [[k [g s]] get-set-map]
                [`(~g [~'this] (~k @~asym))
                 `(~s [~'this ~'v]
                      (swap! ~asym assoc ~k ~'v))])))))))

这在运行时调用编译器，这有点昂贵，但每个要实现的接口只需要执行一次。 结果是一个函数，它接受一个原子作为参数，并使用get-set-map参数中指定的getter和setter实现给定接口的原子周围的包装器。 （以这种方式编写，这比以前的方法灵活性差，但上面的大部分代码都可以在这里重用。）

这是一个示例界面和一个getter / setter映射：

(definterface IFunky
  (getFoo [])
  (^void setFoo [v])
  (getFunkyBar [])
  (^void setWeirdBar [v]))

(def gsm
  '{:foo [getFoo setFoo]
    :bar [getFunkyBar setWeirdBar]})

和一些REPL互动：

user> (def data {:foo 1 :bar 2})
#'user/data
user> (def atom-bean-converter (compile-atom-bean-converter '[IFunky] gsm))
#'user/atom-bean-converter
user> (def atom-bean (atom-bean-converter data))
#'user/atom-bean
user> (.setFoo data-bean 3)
nil
user> (.getFoo atom-bean)
3
user> (.getFunkyBar data-bean)
2
user> (.setWeirdBar data-bean 5)
nil
user> (.getFunkyBar data-bean)
5

Answer 2

重点是作为一个宏本身，它在你自己的set-and-get宏之前扩展 - 所以set-and-get方法不起作用。 因此，在内部宏而不是内部宏中，你需要在“外部”上生成一个用于生成reify的宏。

Answer 3

由于诀窍是在reify看到它之前扩展身体，更通用的解决方案可能是这样的：

(defmacro reify+ [& body]
  `(reify ~@(map macroexpand-1 body)))

Answer 4

您还可以尝试强制您的宏首先展开 ：

(ns qqq (:use clojure.walk))
(defmacro expand-first [the-set & code] `(do ~@(prewalk #(if (and (list? %) (contains? the-set (first %))) (macroexpand-all %) %) code)))

(defmacro setter [setterf kw] `(~setterf [~'this ~'v] (swap! ~'data assoc ~kw ~'v)))
(defmacro getter [getterf kw] `(~getterf [~'this] (~kw @~'data)))
(expand-first #{setter getter} 
 (reify HugeInterface 
  (getter getX :x)
  (setter setX :x)))