[英]Is CDO Email the best way to send email using classic asp?
我正在使用asp创建一个应该将电子邮件发送给多个客户端的网页。 建议我使用CDO电子邮件功能。 这是经典ASP网页的最佳解决方案吗? 或者添加asp.net和ajax来处理这种类型的电子邮件会更好。
CDO将是显而易见的途径。 在.Net Framework的某些版本中,无论如何,ASP.Net只会在CDO周围使用包装器。
我不知道Ajax适合该主题的地方。
粗鲁(最好引用global.asa中的库以获取类型信息并避免使用冗长的Field ID字符串和幻数)示例复制/粘贴且未经我验证:
<%
sch = "http://schemas.microsoft.com/cdo/configuration/"
Set cdoConfig = CreateObject("CDO.Configuration")
With cdoConfig.Fields
.Item(sch & "sendusing") = 2 ' cdoSendUsingPort
.Item(sch & "smtpserver") = "<enter_mail.server_here>"
.Update
End With
Set cdoMessage = CreateObject("CDO.Message")
With cdoMessage
Set .Configuration = cdoConfig
.From = "from@me.com"
.To = "to@me.com"
.Subject = "Sample CDO Message"
.TextBody = "This is a test for CDO.message"
.Send
End With
Set cdoMessage = Nothing
Set cdoConfig = Nothing
%>
它在GoDaddy托管上使用CDO在ASP Classic上以这种方式工作:
<%
Set ObjSendMail = CreateObject("CDO.Message")
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") ="relay-hosting.secureserver.net"
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False
ObjSendMail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
ObjSendMail.Configuration.Fields.Update
'ObjSendMail.AddAttachment mPath, "Logo.gif"
'ObjSendMail.AddAttachment ArrwPath, "red_arrw.gif"
ObjSendMail.Subject = strSub
ObjSendMail.To = strTo
ObjSendMail.From = strFrom
ObjSendMail.Bcc = strBcc
ObjSendMail.Cc = strCc
ObjSendMail.HTMLBody = strMsg
ObjSendMail.Send
Set ObjSendMail = Nothing
%>
您是否要将Ajax添加到ClassicASP? 我会说你在找麻烦。 如果有可能,我鼓励客户转向.net技术。 从长远来看,他们将很感激。
至于CDO对象,请尝试此链接如何使用CDO发送电子邮件?
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.