配置Vim为代码行插入文本

Question

我正在使用Vim进行所有程序编辑，并且在所有源代码文件的顶部都使用了标准标头。 当我使用：w保存任何更改时，我设置了一个.vimrc文件来更新此标头中的某些字段（例如Last Modified）。

我的问题是，如何遵循仅计数非空白行的基本规则，如何放入一个函数来计算代码行？

我知道在打开的vim缓冲区中，我可以使用

:%s/\n//gn 

计算所有行，以及

:%s/\n\n//gn 

计算空白行（基本上是计算一行中出现两个换行符的次数，表示有一个空白行）。 但是，如何将其放入我的.vimrc文件中？

这是我的.vimrc中的代码片段，用于更新标头字段：

function! LastModified()
  if &modified
    let save_cursor = getpos(".")
    let n = min([20, line("$")])
    keepjumps exe '1,' . n . 's#^\(.\{,10}Last Modified:\).*#\1' .
          \ strftime(' %a %b %d, %Y  %I:%M%p') . '#e'
    keepjumps exe '1,' . n . 's#^\(.\{,10}Filename:\).*#\1' .
          \ ' ' . @% . '#e'
    keepjumps exe '1,' . n . 's#^\(.\{,10}LOC:\).*#\1' .
          \ ' ' . '' . '#e'
    call histdel('search', -1)
    call setpos('.', save_cursor)
  endif
endfun

另外，我想补充一下，我知道还有很多其他方法可以做到这一点（例如从外壳中使用wc --lines），但是我有兴趣学习如何真正配置编辑器（因此称之为学习练习） ）。

Answer 1

您实际上不应该在这里使用:s ：

function! CountNonEmpty()
    return len(filter(getline(1, line('$')), '!empty(v:val)'))
endfunction

---

顺便说一句，我会使用getline + map + setline来实现您的标头更新程序：

function! LastModified()
    if &modified
        " If number of buffer lines is < 20, then getline(1, 20)"
        " will return only existing lines without any errors "
        call setline(1, map(getline(1, 20), 'substitute(substitute(substitute(v:val, '.
        \'"^\\v(.{,10}Last Modified:).*", "\\1 ".strftime("%s %b %d, %Y  %I:%M%p"), ""),'.
        \'"^\\v(.{,10}Filename:).*",      "\\1 ".escape(@%, "&\\~"), ""),'.
        \'"^\\v(.{,10}LOC:).*",           "\\1 ", "")'))
    endif
endfunction

Answer 2

这可能会有所帮助：

function! CountNonEmpty()
  redir => g:nonblank
  silent %s/^.\+$/&/n
  redir END
  return substitute(g:nonblank, '\n\s*\(\d\+\)\D.*$', '\1', '')
endfunction

• ：redir =>将以下ex命令的输出存储到给定变量中。 参见:help :redir