Excel VBA将列复制到现有工作簿

Question

我有工作簿， source.xlsm ，工作表“ test1”列A6：A20 ，我需要将其复制到位于我的C：...上的另一个工作簿上，名为dest.xlsx ， 工作表“资产” ， 列“ I” 。 我需要能够复制数据并能够添加到列中，而不会覆盖先前复制的数据。 任何帮助将挽救生命。

Sub Align()
    Dim TargetSh As String

    TargetSh = "Assets"

    For Each WSheet In Application.Worksheets

        If WSheet.Name <> TargetSh Then
            WSheet.Select
            Range("A6:A20").Select
            Range(Selection, ActiveCell.SpecialCells(xlLastCell)).Select
            Selection.Copy
            Sheets(TargetSh).Select
            lastRow = Range("I65532").End(xlUp).Row
            Cells(lastRow + 1, 1).Select
            ActiveSheet.Paste
        End If
    Next WSheet
End Sub

Answer 1

这是您要尝试的吗？ 我没有测试过 ，但我认为它应该可以工作。 让我知道您是否遇到任何错误。

Sub Sample_Copy()
    Dim wb As Workbook, wbTemp As Workbook
    Dim ws As Worksheet, wsTemp As Worksheet
    Dim lastRow As Long

    Set wb = ThisWorkbook
    Set ws = wb.Sheets("test1")

    '~~> Change path as applicable
    Set wbTemp = Workbooks.Open("C:\dest.xlsx")
    Set wsTemp = wbTemp.Sheets("Assets")

    lastRow = wsTemp.Range("I" & Rows.Count).End(xlUp).Row + 1

    ws.Range("A6:A20").Copy wsTemp.Range("I" & lastRow)

    Application.CutCopyMode = False

    '~~> Cleanup
    wbTemp.Close savechanges:=True
    Set wb = Nothing: Set wbTemp = Nothing
    Set ws = Nothing: Set wsTemp = Nothing
End Sub

高温超导

席德