as3 Adob​​e Air访问iPad设备摄像头

Question

有没有一种方法可以使用as3访问iPad的相机？

• 我的意思是在应用程序本身中启动相机
• 有能力拍摄并将图像保存到byteArray并将图像应用于背景或进行一些操作

我已经做了一些研究，其中大多数只是显示如何访问android设备。 感谢您的任何建议或帮助。

Answer 1

是的，您绝对可以做到这一点。 Flash的优点在于，执行此操作的代码与您在Android或PC上使用的代码相同。

从字面上看，您可以执行以下操作将摄像机连接到Video对象：

var camera:Camera = Camera.getCamera();
var video=new Video();
video.attachCamera(camera);
this.addChild(video); // 'this' would be a Sprite or UIComponent, etc...

如果您想做一些有用的事情，还有很多事情要做，但是一旦开始就很简单了:)

Answer 2

bluebill1049，我不能从线程中确定您是否找到了想要的东西，但是我确实看到了您对整个课程的要求。 我在这篇文章中发现了相同的信息（Jason Sturges在他的答案中发布了）。

使用适用于iOS的Adobe Builder（flex）拍照

与这里的回复不同的是，他对该帖子的回复具有指向有关构建移动应用程序的出色教程的链接，并且正是从该教程中取消/引用了这段代码。 它需要一个事件类（event.CameraEvent-仅几行），该事件类包含在该项目/教程中，因此能够像原来一样回到源头很重要。 该来源位于此处：

http://devgirl.org/files/RIAUnleashed/

感谢杰森。 只是您不必进行挖掘，引号中缺少以下事件类：

package events
{
    import flash.events.Event;
    import flash.filesystem.File;

    public class CameraEvent extends Event
    {
        public static const FILE_READY:String = "fileReady";

        public var file:File;

        public function CameraEvent(type:String, file:File=null, bubbles:Boolean = true, cancelable:Boolean = true)
        {
            super(type, bubbles, cancelable);
            this.file = file;
        }
    }
}

希望有帮助！

Answer 3

使用加载程序不是访问iOS上图像字节的唯一方法。 事实证明，数据开始时已经是JPEG格式，因此无需再次编码。

只需执行mediaPromise.open()获取字节并直接保存即可。

Answer 4

XpenseIt示例代码提供了此相机的实现：

类：CameraUtil：

package utils
{
    import events.CameraEvent;

    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.MediaEvent;
    import flash.filesystem.File;
    import flash.filesystem.FileMode;
    import flash.filesystem.FileStream;
    import flash.media.CameraRoll;
    import flash.media.CameraUI;
    import flash.media.MediaPromise;
    import flash.media.MediaType;
    import flash.utils.ByteArray;

    import mx.events.DynamicEvent;
    import mx.graphics.codec.JPEGEncoder;

    [Event(name = "fileReady", type = "events.CameraEvent")]
    public class CameraUtil extends EventDispatcher
    {
        protected var camera:CameraUI;
        protected var loader:Loader;
        public var file:File;

        public function CameraUtil()
        {
            if (CameraUI.isSupported)
            {
                camera = new CameraUI();
                camera.addEventListener(MediaEvent.COMPLETE, mediaEventComplete);
            }
        }

        public function takePicture():void
        {
            if (camera)
                camera.launch(MediaType.IMAGE);
        }

        protected function mediaEventComplete(event:MediaEvent):void
        {
            var mediaPromise:MediaPromise = event.data;
            if (mediaPromise.file == null)
            {
                // For iOS we need to load with a Loader first
                loader = new Loader();
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loaderCompleted);
                loader.loadFilePromise(mediaPromise);
                return;
            }
            else
            {
                // Android we can just dispatch the event that it's complete
                file = new File(mediaPromise.file.url);
                dispatchEvent(new CameraEvent(CameraEvent.FILE_READY, file));
            }
        }

        protected function loaderCompleted(event:Event):void
        {
            var loaderInfo:LoaderInfo = event.target as LoaderInfo;
            if (CameraRoll.supportsAddBitmapData)
            {
                var bitmapData:BitmapData = new BitmapData(loaderInfo.width, loaderInfo.height);
                bitmapData.draw(loaderInfo.loader);
                file = File.applicationStorageDirectory.resolvePath("receipt" + new Date().time + ".jpg");
                var stream:FileStream = new FileStream()
                stream.open(file, FileMode.WRITE);
                var j:JPEGEncoder = new JPEGEncoder();
                var bytes:ByteArray = j.encode(bitmapData);
                stream.writeBytes(bytes, 0, bytes.bytesAvailable);
                stream.close();
                trace(file.url);
                dispatchEvent(new CameraEvent(CameraEvent.FILE_READY, file));
            }
        }

    }
}