基本安装的简单 NSIS 配方

Question

我正准备为我正在开发的游戏开发我的第一个 Windows 安装程序。 我听说过 NSIS 推荐，但我的需求很基本，我无法弄清楚到底需要什么。

我想要一个简短的 NSIS 脚本，它可以在“程序文件”目录中安装一个文件目录（必要时请求权限），在“开始”菜单中创建一个简单的快捷方式，并在“添加/删除程序”控制面板中注册一个卸载程序.

卸载程序只会删除目录并删除快捷方式，如果文件正在使用，则会提示重新启动。

最后，我想通过卸载所有旧文件并安装新文件来支持升级，如果旧文件正在使用，提示用户重新启动。

我在网上看到了一些示例 NSH 脚本，这些脚本会做一些零碎的事情； 我正在尝试自己将它吊在一起，看起来它会有数百行。 我的代码闻起来像是错误的东西。

我描述的程序真的应该是数百行 NSH 吗？ 当然有更简单的方法吗？

Answer 1

下载 Eclipse ，然后将EclipseNSIS 插件安装到 Eclipse 中。 这不仅为您提供了一个功能齐全的 NSIS 文件编辑器（具有代码完成等），而且还有一个向导可以通过回答一些问题（应用程序标题、要使用的图标、... ).

Answer 2

这应该非常接近（我没有测试这个脚本）你应该填写空白并替换某些字符串......

!define Name "Foo"
Name "${Name}"
Outfile "${Name} setup.exe"
RequestExecutionLevel admin ;Require admin rights on NT6+ (When UAC is turned on)
InstallDir "$ProgramFiles\${Name}"

!include LogicLib.nsh
!include MUI.nsh

Function .onInit
SetShellVarContext all
UserInfo::GetAccountType
pop $0
${If} $0 != "admin" ;Require admin rights on NT4+
    MessageBox mb_iconstop "Administrator rights required!"
    SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
    Quit
${EndIf}
FunctionEnd

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Section
SetOutPath "$INSTDIR"
WriteUninstaller "$INSTDIR\Uninstall.exe"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Foo By Bar Inc."   "DisplayName" "${Name}"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Foo By Bar Inc."   "UninstallString" "$INSTDIR\Uninstall.exe"
;TODO: Install your files with the File command
CreateShortCut "$SMPROGRAMS\${Name}.lnk" "$INSTDIR\Foo.exe"
SectionEnd

Section "Uninstall"
;TODO: Delete your files
Delete "$SMPROGRAMS\${Name}.lnk"
DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Foo By Bar Inc."
Delete "$INSTDIR\Uninstall.exe"
RMDir "$INSTDIR"
SectionEnd

Answer 3

NSIS 的一个很棒的向导是 HM NIS Edit，它可以指导您完成第一个安装程序，包括您上面提到的我相信。

http://hmne.sourceforge.net/

如果你想在 NSIS 中提供更新程序，我会推荐一些东西：

1. 为您的应用程序创建一种检查服务器更新的方法，通常在首次加载时完成
2. 下载新的安装程序并运行它（从您的应用程序，尽管任何人也可以从您的网站获得它）。
3. 如果您的旧程序正在运行，您需要将其关闭。 NSIS 有可以找到进程并杀死它的插件。 这不是超级“好”，但可能是必要的。

我推荐这个流程插件

如果您正在使用 DLL，则不能直接删除它们。 但是，在 NSIS 中，您可以重命名它们，然后将它们标记为在 NEXT 重新启动时删除，如下所示：

Delete /REBOOTOK file.txt

然后将新的 DLL 复制到该文件夹中。

对于 NSIS，有大量的插件、示例和很大的帮助，但学习这门语言需要一点时间。 Inno 更容易学习，但当你深入了解细节时更难定制。 但是，我想说这两者总体上是可比的，并且都应该可以正常工作。