如何从VBA打开Windows资源管理器中的文件夹？

Question

我想单击我的访问表单上的一个按钮，以在 Windows Explorer 中打开一个文件夹。

VBA有什么办法吗？

Answer 1

您可以使用以下代码从vba中打开文件位置。

Dim Foldername As String
Foldername = "\\server\Instructions\"

Shell "C:\WINDOWS\explorer.exe """ & Foldername & "", vbNormalFocus

您可以将此代码用于Windows共享和本地驱动器。

如果要最大化视图，可以将VbNormalFocus替换为VbMaximizedFocus。

Answer 2

最简单的方法是

Application.FollowHyperlink [path]

仅需一行！

Answer 3

这是一些更酷的知识：

我遇到这样的情况，我需要能够根据记录中的一些条件查找文件夹，然后打开找到的文件夹。 在寻找解决方案的过程中，我创建了一个小型数据库，该数据库要求搜索起始文件夹为4条条件提供一个位置，然后允许用户进行条件匹配，从而打开与输入的4个（或更多个）可能匹配的文件夹标准。

这是表格上的整个代码：

Option Compare Database
Option Explicit

Private Sub cmdChooseFolder_Click()

    Dim inputFileDialog As FileDialog
    Dim folderChosenPath As Variant

    If MsgBox("Clear List?", vbYesNo, "Clear List") = vbYes Then DoCmd.RunSQL "DELETE * FROM tblFileList"
    Me.sfrmFolderList.Requery

    Set inputFileDialog = Application.FileDialog(msoFileDialogFolderPicker)

    With inputFileDialog
        .Title = "Select Folder to Start with"
        .AllowMultiSelect = False
        If .Show = False Then Exit Sub
        folderChosenPath = .SelectedItems(1)
    End With

    Me.txtStartPath = folderChosenPath

    Call subListFolders(Me.txtStartPath, 1)

End Sub
Private Sub cmdFindFolderPiece_Click()

    Dim strCriteria As String
    Dim varCriteria As Variant
    Dim varIndex As Variant
    Dim intIndex As Integer

    varCriteria = Array(Nz(Me.txtSerial, "Null"), Nz(Me.txtCustomerOrder, "Null"), Nz(Me.txtAXProject, "Null"), Nz(Me.txtWorkOrder, "Null"))
    intIndex = 0

    For Each varIndex In varCriteria
        strCriteria = varCriteria(intIndex)
        If strCriteria <> "Null" Then
            Call fnFindFoldersWithCriteria(TrailingSlash(Me.txtStartPath), strCriteria, 1)
        End If
        intIndex = intIndex + 1
    Next varIndex

    Set varIndex = Nothing
    Set varCriteria = Nothing
    strCriteria = ""

End Sub
Private Function fnFindFoldersWithCriteria(ByVal strStartPath As String, ByVal strCriteria As String, intCounter As Integer)

    Dim fso As New FileSystemObject
    Dim fldrStartFolder As Folder
    Dim subfldrInStart As Folder
    Dim subfldrInSubFolder As Folder
    Dim subfldrInSubSubFolder As String
    Dim strActionLog As String

    Set fldrStartFolder = fso.GetFolder(strStartPath)

'    Debug.Print "Criteria: " & Replace(strCriteria, " ", "", 1, , vbTextCompare) & " and Folder Name is " & Replace(fldrStartFolder.Name, " ", "", 1, , vbTextCompare) & " and Path is: " & fldrStartFolder.Path

    If fnCompareCriteriaWithFolderName(fldrStartFolder.Name, strCriteria) Then
'        Debug.Print "Found and Opening: " & fldrStartFolder.Name & "Because of: " & strCriteria
        Shell "EXPLORER.EXE" & " " & Chr(34) & fldrStartFolder.Path & Chr(34), vbNormalFocus
    Else
        For Each subfldrInStart In fldrStartFolder.SubFolders

            intCounter = intCounter + 1

            Debug.Print "Criteria: " & Replace(strCriteria, " ", "", 1, , vbTextCompare) & " and Folder Name is " & Replace(subfldrInStart.Name, " ", "", 1, , vbTextCompare) & " and Path is: " & fldrStartFolder.Path

            If fnCompareCriteriaWithFolderName(subfldrInStart.Name, strCriteria) Then
'                Debug.Print "Found and Opening: " & subfldrInStart.Name & "Because of: " & strCriteria
                Shell "EXPLORER.EXE" & " " & Chr(34) & subfldrInStart.Path & Chr(34), vbNormalFocus
            Else
                Call fnFindFoldersWithCriteria(subfldrInStart, strCriteria, intCounter)
            End If
            Me.txtProcessed = intCounter
            Me.txtProcessed.Requery
        Next
    End If

    Set fldrStartFolder = Nothing
    Set subfldrInStart = Nothing
    Set subfldrInSubFolder = Nothing
    Set fso = Nothing

End Function
Private Function fnCompareCriteriaWithFolderName(strFolderName As String, strCriteria As String) As Boolean

    fnCompareCriteriaWithFolderName = False

    fnCompareCriteriaWithFolderName = InStr(1, Replace(strFolderName, " ", "", 1, , vbTextCompare), Replace(strCriteria, " ", "", 1, , vbTextCompare), vbTextCompare) > 0

End Function

Private Sub subListFolders(ByVal strFolders As String, intCounter As Integer)
    Dim dbs As Database
    Dim fso As New FileSystemObject
    Dim fldFolders As Folder
    Dim fldr As Folder
    Dim subfldr As Folder
    Dim sfldFolders As String
    Dim strSQL As String

    Set fldFolders = fso.GetFolder(TrailingSlash(strFolders))
    Set dbs = CurrentDb

    strSQL = "INSERT INTO tblFileList (FilePath, FileName, FolderSize) VALUES (" & Chr(34) & fldFolders.Path & Chr(34) & ", " & Chr(34) & fldFolders.Name & Chr(34) & ", '" & fldFolders.Size & "')"
    dbs.Execute strSQL

    For Each fldr In fldFolders.SubFolders
        intCounter = intCounter + 1
        strSQL = "INSERT INTO tblFileList (FilePath, FileName, FolderSize) VALUES (" & Chr(34) & fldr.Path & Chr(34) & ", " & Chr(34) & fldr.Name & Chr(34) & ", '" & fldr.Size & "')"
        dbs.Execute strSQL
        For Each subfldr In fldr.SubFolders
            intCounter = intCounter + 1
            sfldFolders = subfldr.Path
            Call subListFolders(sfldFolders, intCounter)
            Me.sfrmFolderList.Requery
        Next
        Me.txtListed = intCounter
        Me.txtListed.Requery
    Next

    Set fldFolders = Nothing
    Set fldr = Nothing
    Set subfldr = Nothing
    Set dbs = Nothing

End Sub

Private Function TrailingSlash(varIn As Variant) As String
    If Len(varIn) > 0& Then
        If Right(varIn, 1&) = "\" Then
            TrailingSlash = varIn
        Else
            TrailingSlash = varIn & "\"
        End If
    End If
End Function

该表单具有一个基于表的子表单，该表单具有4个用于条件的文本框，2个用于单击过程的按钮和1个用于存储起始文件夹字符串的其他文本框。 有2个文本框，用于显示列出的文件夹数量和在搜索条件时处理的数量。

如果我有代表，我会发布图片...：/

我还有其他想添加到此代码中的内容，但还没有机会。 我想要一种方法来存储在另一个表中工作过的那些，或者让用户将它们标记为好存储。

我不能对所有代码都称赞，我从周围发现的东西中整理了一些代码，即使在stackoverflow上的其他帖子中也是如此。

我真的很喜欢在这里发布问题然后自己回答的想法，因为如链接文章所述，它很容易找到答案供以后参考。

当我完成其他要添加的部分时，我也将发布该代码。 :)

Answer 4

多亏了PhilHibbs的评论（关于VBwhatnow的回答），我终于找到了一个既可以重用现有窗口又可以避免向用户刷新CMD窗口的解决方案：

Dim path As String
path = CurrentProject.path & "\"
Shell "cmd /C start """" /max """ & path & """", vbHide

其中“路径”是您要打开的文件夹。

（在此示例中，我打开了保存当前工作簿的文件夹。）

优点：

• 避免打开新的资源管理器实例（仅在存在窗口时设置焦点）。
• 借助vbHide，cmd窗口将永远不可见。
• 比较简单（不需要引用win32库）。

缺点：

• 窗口最大化（或最小化）是强制性的。

说明：

最初，我尝试仅使用vbHide。 效果很好...除非已经打开了这样一个文件夹，否则现有文件夹窗口将被隐藏并消失！ 现在，您将在内存中浮动一个幻影窗口，此后任何随后尝试打开该文件夹的尝试都会重用隐藏的窗口-似乎没有任何作用。

换句话说，当“start'-命令找到指定vbAppWinStyle被应用到CMD-窗口和重新使用浏览器窗口都现有的窗口。 （因此，幸运的是，可以通过使用不同的vbAppWinStyle参数再次调用同一命令来取消隐藏窗口。）

但是，通过在调用“开始”时指定/ max或/ min标志，可以防止在CMD窗口上设置的vbAppWinStyle递归应用。 （或覆盖它？我不知道技术细节是什么，我很好奇确切地知道这里的事件链是什么。）

Answer 5

这是我所做的。

Dim strPath As String
strPath = "\\server\Instructions\"    
Shell "cmd.exe /c start """" """ & strPath & """", vbNormalFocus

优点：

• 避免打开新的资源管理器实例（仅在存在窗口时设置焦点）。
• 比较简单（不需要引用win32库）。
• 窗口最大化（或最小化） 不是强制性的。 窗口将以正常大小打开。

缺点：

• 该cmd窗口在短时间内可见。

如果没有打开该文件夹，则始终打开该文件夹的窗口；如果该文件夹没有打开，则切换到打开的窗口。

感谢PhilHibbs和AnorZaken为这一基础。 PhilHibbs的注释对我来说不太有效，我需要在命令字符串中的文件夹名称前加上双引号。 而且我更喜欢让命令提示符窗口出现一点，而不是被迫最大化或最小化资源管理器窗口。

Answer 6

Shell "C:\WINDOWS\explorer.exe /select,""" & ActiveWorkbook.Name & "", vbNormalFocus

Answer 7

这是一个给出“开始”的切换或启动行为的答案，而没有“命令提示符”窗口。 它确实具有一个缺点，即可以被在其他位置打开了同名文件夹的资源管理器窗口欺骗。 我可能会通过进入子窗口并寻找实际路径来解决此问题，我需要弄清楚如何进行导航。

用法（需要项目参考中的“ Windows脚本宿主对象模型”）：

Dim mShell As wshShell

mDocPath = whatever_path & "\" & lastfoldername
mExplorerPath = mShell.ExpandEnvironmentStrings("%SystemRoot%") & "\Explorer.exe"

If Not SwitchToFolder(lastfoldername) Then
    Shell PathName:=mExplorerPath & " """ & mDocPath & """", WindowStyle:=vbNormalFocus
End If

模块：

Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" _
(ByVal hWnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function BringWindowToTop Lib "user32" _
(ByVal lngHWnd As Long) As Long

Function SwitchToFolder(pFolder As String) As Boolean

Dim hWnd As Long
Dim mRet As Long
Dim mText As String
Dim mWinClass As String
Dim mWinTitle As String

    SwitchToFolder = False

    hWnd = FindWindowEx(0, 0&, vbNullString, vbNullString)
    While hWnd <> 0 And SwitchToFolder = False
        mText = String(100, Chr(0))
        mRet = GetClassName(hWnd, mText, 100)
        mWinClass = Left(mText, mRet)
        If mWinClass = "CabinetWClass" Then
            mText = String(100, Chr(0))
            mRet = GetWindowText(hWnd, mText, 100)
            If mRet > 0 Then
                mWinTitle = Left(mText, mRet)
                If UCase(mWinTitle) = UCase(pFolder) Or _
                   UCase(Right(mWinTitle, Len(pFolder) + 1)) = "\" & UCase(pFolder) Then
                    BringWindowToTop hWnd
                    SwitchToFolder = True
                End If
            End If
        End If
        hWnd = FindWindowEx(0, hWnd, vbNullString, vbNullString)
    Wend

End Function

Answer 8

私人子Command0_Click（）

Application.FollowHyperlink“ D：\\ 1Zsnsn \\ SusuBarokah \\ 20151008 Inventory.mdb”

结束子

Answer 9

由于公司的安全性，我可能不使用shell命令，所以这是我在Internet上找到的最佳方法。

Sub OpenFileOrFolderOrWebsite() 
'Shows how to open files and / or folders and / or websites / or create    emails using the FollowHyperlink method
Dim strXLSFile As String, strPDFFile As String, strFolder As String, strWebsite As String 
Dim strEmail As String, strSubject As String, strEmailHyperlink As     String 

strFolder = "C:\Test Files\" 
strXLSFile = strFolder & "Test1.xls" 
strPDFFile = strFolder & "Test.pdf" 
strWebsite = "http://www.blalba.com/" 

strEmail = "mailto:YourEmailHere@Website.com" 
strSubject = "?subject=Test" 
strEmailHyperlink = strEmail & strSubject 

 '**************FEEL FREE TO COMMENT ANY OF THESE TO TEST JUST ONE ITEM*********
 'Open Folder
ActiveWorkbook.FollowHyperlink Address:=strFolder, NewWindow:=True 
 'Open excel workbook
ActiveWorkbook.FollowHyperlink Address:=strXLSFile, NewWindow:=True 
 'Open PDF file
ActiveWorkbook.FollowHyperlink Address:=strPDFFile, NewWindow:=True 
 'Open VBAX
ActiveWorkbook.FollowHyperlink Address:=strWebsite, NewWindow:=True 
 'Create New Email
ActiveWorkbook.FollowHyperlink Address:=strEmailHyperlink, NewWindow:=True 
 '******************************************************************************
End Sub 

所以实际上它

strFolder = "C:\Test Files\"

和

ActiveWorkbook.FollowHyperlink Address:=strFolder, NewWindow:=True 

Answer 10

我只是用这个，它工作正常：

System.Diagnostics.Process.Start（“ C：/ Users / Admin / files”）;

Answer 11

由于上面和其他地方的许多答案，这是我对与OP类似问题的解决方案。 我的问题是在Word中创建一个按钮，该按钮要求用户提供网络地址，并在资源管理器窗口中拉出LAN资源。

原始代码不会带您进入\\\\10.1.1.1\\Test,因此请根据需要进行编辑。 我只是键盘上的猴子，在这里，欢迎提出所有意见和建议。

Private Sub CommandButton1_Click()
    Dim ipAddress As Variant
    On Error GoTo ErrorHandler

    ipAddress = InputBox("Please enter the IP address of the network resource:", "Explore a network resource", "\\10.1.1.1")
    If ipAddress <> "" Then
        ThisDocument.FollowHyperlink ipAddress & "\Test"
    End If

    ExitPoint:
        Exit Sub

    ErrorHandler:
        If Err.Number = "4120" Then
            GoTo ExitPoint
        ElseIf Err.Number = "4198" Then
            MsgBox "Destination unavailable"
            GoTo ExitPoint
        End If

        MsgBox "Error " & Err.Number & vbCrLf & Err.Description
        Resume ExitPoint

End Sub

Answer 12

您可以使用命令提示符打开带有路径的资源管理器。

这是批处理或命令提示符的示例：

start "" explorer.exe (path)

因此，在VBA ms.access中，您可以编写：

Dim Path
Path="C:\Example"
shell "cmd /c start """" explorer.exe " & Path ,vbHide