VBS和XPath处理多个XML文件

Question

该脚本通过Windows子文件夹查找XML文件。 循环应加载XML文件并执行操作，然后传递到下一个XML文件，依此类推。

这条线没有按照我希望的方式进行解释：

If oXML.load(objFile.name) Then
WScript.Echo "XML file loaded"

编写此代码的正确方法是什么？

这是完整的脚本。

Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\test_env"

set oXML = CreateObject("Msxml2.DOMDocument")
oXML.async = "false"

Set objFolder = objFSO.GetFolder(objStartFolder)
Wscript.Echo objFolder.Path
Set colFiles = objFolder.Files
For Each objFile in colFiles
    Wscript.Echo objFile.Name
Next
Wscript.Echo

ShowSubfolders objFSO.GetFolder(objStartFolder)

Sub ShowSubFolders(Folder)
    For Each Subfolder in Folder.SubFolders
        Set objFolder = objFSO.GetFolder(Subfolder.Path)
        Set colFiles = objFolder.Files
        For Each objFile in colFiles
            If UCase(objFSO.GetExtensionName(objFile.name)) = "XML" Then
               Wscript.Echo Subfolder.Path
               Wscript.Echo objFile.Name
               ' LOAD THE XML FILE
               If oXML.load(objFile.name) Then
               WScript.Echo "XML loaded"
               Else WScript.Echo "XML not loaded"
              End If
            End If
        Next
        ShowSubFolders Subfolder
    Next
End Sub 

提前致谢。

Answer 1

.load方法需要.xml文件的完整路径，因此请进行更改

If oXML.load(objFile.name) Then

至

If oXML.load(objFile.Path) Then

如果发生故障， .parseError.reason查看.parseError.reason 。