运行时错误'1004'：对象'_Global'的方法'Range'失败

Question

我对excel有问题，它的表单会生成参考号。 但是当我尝试生成参考号时。 它显示一条错误消息：

运行时错误'1004'：对象'_Global'的方法'Range'失败

当我点击Debug按钮时，它显示如下代码：

它突出显示了代码第四行的错误

Sub clearTemplate()
    ' Clear Template Content
    Range(inputTemplateHeader) = NO_ENTRY
    Range(inputTemplateContent) = NO_ENTRY     - (highlighted error)
End Sub

Sub clearRefNo()
    ' Clear cell G2 reference number
    Range(cellRefNo) = NO_ENTRY

    ' Open "Report_ref_no.xls"
    If Not (IsFileOpen) Then Workbooks.Open filename:=ThisWorkbook.Path & "\" & FACCESS

    ' Activate "Report_ref_no.xls"
    Windows(FACCESS).Activate

    ' Access column D
    Range(cellFirstRefNo).Select
    Selection.End(xlDown).Select

    If refNo = Cells(ActiveCell.Row, ActiveCell.Column - 1).Value Then
        ' Log Development Code column
        Cells(ActiveCell.Row, ActiveCell.Column) = NO_ENTRY

        ' Log Issuer column
        Cells(ActiveCell.Row, ActiveCell.Column + 1).Value = NO_ENTRY

        ' Log Date column
        Cells(ActiveCell.Row, ActiveCell.Column + 2).Value = NO_ENTRY
    End If

    ' Save & Close workbook
    ActiveWindow.Close True
End Sub

谁能帮助我解决这个问题？ 我不知道出了什么问题？

Answer 1

当您像这样引用Range时，它被称为不合格引用，因为您没有具体说出该范围在哪张纸上。 不合格的引用由“ _Global”对象处理，该对象确定要引用的对象，并取决于代码的位置。

如果您使用的是标准模块，则不合格的范围将引用Activesheet。 如果您在工作表的班级模块中，则不合格的范围将引用该工作表。

inputTemplateContent是一个变量，包含对范围（可能是命名范围）的引用。 如果查看该命名范围的RefersTo属性，则在执行代码时，它可能指向除Activesheet之外的工作表。

解决此问题的最佳方法是通过指定工作表来避免使用不合格的范围引用。 喜欢

With ThisWorkbook.Worksheets("Template")
    .Range(inputTemplateHeader).Value = NO_ENTRY
    .Range(inputTemplateContent).Value = NO_ENTRY
End With

调整工作簿和工作表引用以适合您的特定情况。