Haskell：列表模式匹配

Question

我正在尝试创建一个接收列表的函数，如果其中一个元素为负，则该列表中与其正对应项相等的任何元素都应更改为 0。例如，如果有 -2在列表中，则该列表中的所有 2 都应更改为 0。

任何想法为什么它只适用于某些情况而不适用于其他情况？ 我不明白这是为什么，我已经看了好几遍了。

changeToZero [] = []
changeToZero [x] = [x]
changeToZero (x:zs:y:ws) | (x < 0) && ((-1)*(x) == y) = x : zs : 0 : changeToZero ws
changeToZero (x:xs) = x : changeToZero xs

changeToZero [-1,1,-2,2,-3,3]
-- [-1,1,-2,2,-3,3]

changeToZero [-2,1,2,3]
-- [-2,1,0,3]

changeToZero [-2,1,2,3,2]
-- [-2,1,0,3,2]

changeToZero [1,-2,2,2,1]
-- [1,-2,2,0,1]

Answer 1

我认为列表理解在这里更清晰、更容易。

changeToZero xs = [if x > 0 && (-x) `elem` xs then 0 else x | x <- xs]

如果您需要更有效的东西，您可以构建一组否定元素并检查它而不是使用elem 。

import qualified Data.Set as Set

changeToZero' xs = [if (-x) `Set.member` unwanted then 0 else x | x <- xs]
  where unwanted = Set.fromList $ filter (< 0) xs

Answer 2

你实际上不记得你在列表中找到了哪些负面符号

import qualified Data.Set as S

changeToZero :: [Int] -> [Int]
changeToZero [] = []
changeToZero xs = reverse . snd $ foldl f (S.empty,[]) xs
  where
    f (negs,res) x | x < 0 = (S.insert (-x) negs, x:res)
                   | S.member x negs = (negs,0:res)
                   | otherwise = (negs,x:res)

Answer 3

好吧，基于@jdevelop 的答案，如果负数必须出现在正数之前才能计数，那么您可以通过输入一次构建结果，而无需反转它：

import qualified Data.Set as S
import Control.Monad.State

changeToZero :: [Int] -> [Int]
changeToZero xs = evalState (mapM f xs) S.empty where
  f x | x < 0     = modify (S.insert (-x)) >> return x
      | otherwise = gets (S.member x) >>= \hasNeg -> return $ if hasNeg then 0 else x

通过这种方式，您可以得到答案

take 4 $ changeToZero $ 1 : (-2) : 3 : 2 : undefined

其他解决方案将失败的地方。

** 编辑 **

这是同样的事情，但没有State monad，这使得它更容易理解：

changeToZero' :: [Int] -> [Int]
changeToZero' = go S.empty where
  go _ [] = []
  go s (x:xs) | x < 0        = x : go (S.insert (-x) s) xs
              | S.member x s = 0 : go s xs
              | otherwise    = x : go s xs