使用 CMake 编译 /MT 而不是 /MD

Question

我在带有 Windows SDK 和 NMake Makefiles 的 Windows 上使用 CMake。

默认情况下，它使用/MD编译器开关进行编译。

如何更改它以使用/MT开关编译？

Answer 1

您可以修改CMAKE_CXX_FLAGS_<Build Type>和/或CMAKE_C_FLAGS_<Build Type>变量：

set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

如果您的 CMake 标志已经包含/MD ，您可以确保在插入/MD的点之后执行上述命令（后来添加的/MT覆盖了冲突的现有选项），或者您可以从头开始设置标志：

set(CMAKE_CXX_FLAGS_RELEASE "/MT")
set(CMAKE_CXX_FLAGS_DEBUG "/MTd")

或者，您可以通过执行/MTd分别用/MT和/MTd替换现有的/MD和/MDd值：

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        )
foreach(CompilerFlag ${CompilerFlags})
  string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
endforeach()

Answer 2

CMake 最终在版本 3.15 中使用MSVC_RUNTIME_LIBRARY目标属性添加了对此的适当支持：

cmake_minimum_required(VERSION 3.15)
cmake_policy(SET CMP0091 NEW)
project(my_project)

add_executable(foo foo.c)
set_property(TARGET foo PROPERTY
             MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

您还可以通过设置CMAKE_MSVC_RUNTIME_LIBRARY变量来指定全局默认值。

Answer 3

似乎对于Visual Studio 15 2017和CMake 3.12 ，将/MD替换为/MT是将此代码段添加到 CMakeLists.txt 文件中：

if(MSVC)
    add_compile_options(
        $<$<CONFIG:>:/MT> #---------|
        $<$<CONFIG:Debug>:/MTd> #---|-- Statically link the runtime libraries
        $<$<CONFIG:Release>:/MT> #--|
    )
endif()

我在官方 CMake 存储库中找到了这个解决方案： https : //gitlab.kitware.com/cmake/cmake/issues/18390

Answer 4

查看ucm_set_runtime - 此宏将替换静态或动态运行时的标志 - 要查看效果，请使用ucm_print_flags （也请查看此堆栈溢出问题）。

Answer 5

我必须使用set( ... CACHE ... FORCE)来覆盖 MSVC 的默认缓存。

如果我不使用这种方法，MSVC 仍然会输出/MD选项。

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_CXX_FLAGS_MINSIZEREL
        CMAKE_CXX_FLAGS_RELWITHDEBINFO
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        CMAKE_C_FLAGS_MINSIZEREL
        CMAKE_C_FLAGS_RELWITHDEBINFO
        )
foreach(CompilerFlag ${CompilerFlags})
    string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
    set(${CompilerFlag} "${${CompilerFlag}}" CACHE STRING "msvc compiler flags" FORCE)
    message("MSVC flags: ${CompilerFlag}:${${CompilerFlag}}")
endforeach()

Answer 6

从 cmacke 3.15 开始，您可以使用MSVC_RUNTIME_LIBRARY 。 见https://cmake.org/cmake/help/latest/prop_tgt/MSVC_RUNTIME_LIBRARY.html