從包含N的表列中選擇前N行

Question

TSQL 2008 R2

我有重復的訂單項，每個訂單項都有自己的給定PO＃的唯一ID。 我需要刪除重復項。 我不知道每個PO＃有多少重復。 因為有一個#LineItems我知道我只想要第一個（頂部）x（#lineIems）行項目。

我有一張像這樣的桌子：

LineitemID PO#     #LineItems
---------- ------- ----------
11111111   12345   3
22222222   12345   3
33333333   12345   3
44444444   12345   3
55555555   12345   3
66666666   12345   3
77777777   54321   2
88888888   54321   2
99999999   54321   2
10101010   54321   2
...  

我需要這樣一張桌子：

LineitemID PO#     #LineItems
---------- ------- ----------
11111111   12345   3
22222222   12345   3
33333333   12345   3
77777777   54321   2
88888888   54321   2
...  

所以基本上有辦法做這樣的事情：

DECLARE @top int = (SELECT TOP 1 FROM tblLineItems t WHERE t.PO# = @PO)

SELECT TOP (@top)
FROM tblLineItems

並按照每個PO＃執行此操作

Answer 1

delete t from (select *, rank = row_number() over (partition by PO# order by lineitemid) 
               from table ) t 
where rank > #lineitems

Answer 2

在facepalm之后刪除了第一個答案。

您的示例唯一的問題是您在TOP查詢中沒有ORDER BY，這可能會以任何順序拉出結果。 此查詢假定您按LineItemID（整數類型）ASC進行排序。

DECLARE @LineItems TABLE
(
    LineItemID INT
    , PO INT
    , NumLineItems INT
)

INSERT INTO @LineItems (LineItemID, PO, NumLineItems)
SELECT 11111111,   12345,   3
UNION ALL SELECT 22222222,   12345,   3
UNION ALL SELECT 33333333,   12345,   3
UNION ALL SELECT 44444444,   12345,   3
UNION ALL SELECT 55555555,   12345,   3
UNION ALL SELECT 66666666,   12345,   3
UNION ALL SELECT 77777777,   54321,   2
UNION ALL SELECT 88888888,   54321,   2
UNION ALL SELECT 99999999,   54321,   2
UNION ALL SELECT 10101010,   54321,   2

DELETE b
FROM
(
    SELECT *
        , RANK() OVER (PARTITION BY PO, NumLineItems ORDER BY LineItemID ASC) AS r
    FROM @LineItems
) a
JOIN @LineItems b
    ON a.LineItemID = b.LineItemID
WHERE r > a.NumLineItems

SELECT *
FROM @LineItems
ORDER BY PO, LineItemID