為什么在Erlang中不能生成/ 3（MFA）？

Question

這是Erlang中的一個簡單服務器。 我正在嘗試使用spawn / 3進行生成，但是我必須求助於使用spawn / 1才能使其正常工作。

-module(server_by_name).
-export([start/0]).

start() ->
    {ok, Listen} = gen_tcp:listen(1234, [binary, {packet, 0}, {reuseaddr, true}, {active, true}]),
    io:format("Server running."),
    % --> Why doesn't this work in place of the line below? --> spawn(server_by_name, connect, [Listen]).
    spawn(fun() -> connect(Listen) end).

connect(Listen) ->
    {ok, Socket} = gen_tcp:accept(Listen),
    spawn(fun() -> connect(Listen) end),
    io:format("Connection accepted on ~p Pid ~p~n", [Socket, self()]),
    receive
        {tcp, Socket, Bin} ->
            Request = parse_request(Bin),
            io:format("File requested: ~p~n", [Request]),
            LoadHtml = file:read_file(Request),
            case LoadHtml of
                {ok, Reply} ->
                    Header = "HTTP/1.1 200 OK \r\n Content-Type:HTML\r\n\r\n",
                    ConnectCheck = gen_tcp:send(Socket, Header ++ Reply),
                    io:format("Connection?? ~p~n", [ConnectCheck]);
                {error, Reason} ->
                    io:format("Error in loading html file: ~n~p~n", [Reason]);
            end;
        {tcp_closed, Socket} ->
            io:format("Server socket closed~n")
    after 5000 ->
        io:format("Client unresponsive~n")
    end.

parse_request(Bin) when is_binary(Bin)->
    parse_request(binary_to_list(Bin));

parse_request("GET /" ++ RestStr) ->
    get_request([], RestStr);

parse_request([_H|T]) ->
    parse_request(T).

get_request(Request, [32|_RestStr]) ->
    lists:reverse(Request);

get_request(Request, [H|RestStr]) ->
    get_request([H|Request], RestStr);

get_request(Request, []) ->
    io:format("Unexpected result in server_by_name:get_request()"),
    list:reverse(Request).

我已包含所有代碼，因此您可以復制/粘貼它，並在需要時自己嘗試。 您只需要有一個可在同一目錄中提供的文件，然后按名稱請求即可。 顯然，它沒有安全預防措施等。

Answer 1

spawn/3要求導出功能。 您的解決方案是完全合理的，但您也可以導出connect/1 ：

-export([connect/1]).  %% do not use, exported for spawn