使用 Net::SFTP::Foreign 下載 Perl sftp

Question

我是初學者。 我寫了一個 perl 腳本，它執行以下操作

-按當前日期在“/x01/abcd/abc_logs/abcd_Logs”下創建一個目錄，如果尚未創建，格式為“YYYYMMDD”。 即：如果腳本在“01st of jan 2013”​​運行，將在上述路徑下創建目錄“20130101”。 因此，每當需要檢查日志時，請始終按當前日期查找目錄。

- 檢查日志文件是否已經在當天早些時候下載，如果沒有，日志將下載到今天的目錄。

我很難，想出一個解決方案來在共享中沒有文件時打印消息。 這當然是當用戶指定共享中不存在的 2 個或更多文件時。 我知道發生這種情況是因為“sub get_LOGS”中有一個“die”語句。 當我指定的所有文件都沒有在共享中時，我似乎無法理解如何返回消息。

這個腳本的用法如下

./abc_logs ....<文件(n)>

以下是腳本。

my $LOGS_LOCAL_PATH = "/x02/abc/abcba2/";
chomp $LOGS_LOCAL_PATH;
my $LOGS_REM_PATH = "/x01/INT/abc/vabc2/";
chomp $LOGS_REM_PATH;
my $TODAY = `date +%Y%m%d`;
chomp $TODAY;
my @GETLOOP = @ARGV;
    unless ($#ARGV >= 0) {
        print "\nUsage: gtp_logs.pl <file1> <file2> <file3>.....<file(n)>\n\n";
        exit;
    }
        system("clear");
    unless ( -d "$LOGS_LOCAL_PATH"."$TODAY") {
        print "Directory \"$TODAY\" doesn't exist. So creating the directory..!\n";
        print "OK..Done.....!\n\n";
        system("mkdir $LOGS_LOCAL_PATH/$TODAY");
        }
    else {
        print "Directory already exists. Logs will be downloaded to ==>     \"$LOGS_LOCAL_PATH$TODAY\".....!\n\n";
    }
    
               # if_DOWNLOADED($LOGS_LOCAL_PATH,$TODAY,@GETLOOP);
    
    chdir("$LOGS_LOCAL_PATH"."$TODAY") || die "cannot cd to  ($!)";
    foreach my $GETL (@GETLOOP) {
    my $is_downloaded = if_DOWNLOADED($LOGS_LOCAL_PATH,$TODAY,$GETL);
    if(!$is_downloaded)
    {
        get_LOGS("172.25.70.221","abc","abc2","/x01/INT/abc",$GETL);
        print "File \"$GETL\" downloaded to ==>          \"$LOGS_LOCAL_PATH$TODAY\"\n\n";
    }
    else
    {
        print "File \"$GETL\" has already been Downloaded to ==>          \"$LOGS_LOCAL_PATH$TODAY\"\n\n";
    }
    
    
    }
    

 sub get_LOGS {
    my $LOG_HOST  = shift;
    my $REM_USER  = shift;
    my $REM_PASSW = shift;
    my $REM_PATH  = shift;
    my $REM_FILE  = shift;
    
        print "Connecting to the sftp share! Please wait....!\n";
        my $sftp = Net::SFTP::Foreign->new($LOG_HOST, user => $REM_USER, password => $REM_PASSW);
        $sftp->setcwd($REM_PATH) or die "unable to change cwd: " . $sftp->error;
        print "OK. On the share! Downloading the file \"$REM_FILE\"...................!\n\n\n\n";
        $sftp->error and die "Problem connecting to the share...!!!! " . $sftp->error;
        $sftp->get($REM_FILE) or die "File does not seem to be present on the remote share. Please re-request..!!!" . $sftp->error;
        return $REM_FILE;
}
   
sub if_DOWNLOADED {
    my $DWD_FILE_PATH = shift;
    my $DWD_DIR       = shift;
    my $DWD_FILE      = shift;
    if (-e "$DWD_FILE_PATH/$DWD_DIR/$DWD_FILE")
    {
        return 1;
    }
    else
    {
        return 0;
    }
}

請有人幫我找到解決這個問題的方法嗎？ 請嘗試使用相同的腳本並進行修改。

/V

Answer 1

對您的代碼的一些評論：

• 使用嚴格和警告以便及早發現大量錯誤。

• 閱讀一些關於風格的書（即 Damian Conway 的 Perl Best Practices）。 但無論如何，在命名變量、子例程和所有內容以及它們的大小寫時，請盡量保持一致。

• 當您必須在多個地方使用某個計算值時，請嘗試計算一次並將其保存在變量中。

• 不要將子程序用於瑣碎的事情。

• 您不需要對已定義且末尾沒有"\\n"字符的變量調用chomp 。

• 為每個文件傳輸打開一個新的 SFTP 連接是非常低效的。 您可以在開始時只打開一個並將其用於所有傳輸。

現在，腳本的簡化版本：

#!/usr/bin/perl

use strict;
use warnings;

my $host = "172.25.70.221";
my $user = "abc";
my $password = "abc1234321";

my $LOGS_LOCAL_PATH = "/x02/ABC/abc2";
my $LOGS_REM_PATH = "/x01/INT/abc/vim";
my $TODAY = `date +%Y%m%d`;
chomp $TODAY;
my $TODAY_LOCAL_PATH = "$LOGS_LOCAL_PATH/$TODAY";

my @files = @ARGV;
@files or die "\nUsage: gtp_logs.pl <file1> <file2> <file3>.....<file(n)>\n\n";

system("clear");

if ( -d $TODAY_LOCAL_PATH) {
    print "Directory already exists. Logs will be downloaded to ==>     \"$TODAY_LOCAL_PATH\".....!\n\n";
}
else {
    print "Directory \"$TODAY\" doesn't exist. So creating the directory..!\n";
    mkdir "$TODAY_LOCAL_PATH" or die "unable to create directory: $!\n";
    print "OK..Done.....!\n\n";
}

chdir $TODAY_LOCAL_PATH or die "cannot cd to  ($!)\n";

my $sftp =  Net::SFTP::Foreign->new($host, user => $user, password => $password);
$sftp->error
    and die "Problem connecting to the share...!!!! " . $sftp->error;

my $ok = 0;
my $failed = 0;
foreach my $file (@files) {
    if (-e "$TODAY_LOCAL_PATH/$file") {
        print "File \"$file\" has already been Downloaded to ==>          \"$TODAY_LOCAL_PATH\"\n";
    }
    else {
        if ($sftp->get("$LOGS_REM_PATH/$file")) {
            print "File \"$file\" downloaded to ==>          \"$TODAY_LOCAL_PATH\"\n";
            $ok++;
        }
        else {
            print "Unable to download file \"$file\" : " . $sftp->error . "\n";
            $failed++;
        }
    }
}

print "$ok files have been downloaded, $failed files failed!\n\n";