在 Excel 2007 中，如何對命名范圍中的多列進行 SUMIFS 索引？

Question

我正在分析與特定用戶類別的貸款相關的圖書館統計數據。 貸款數據形成命名范圍 LoansToApril2013。 Excel 2007 很高興我使用索引范圍作為 SUMIF 中的總和范圍：

=SUMIF(INDEX(LoansToApril2013,0,3),10,INDEX(LoansToApril2013,0,4):INDEX(LoansToApril2013,0,6))

這里的 10 表示一個特定的用戶類別，它匯總了三列向該組發放的貸款。 通過“索引范圍”，我指的是

INDEX(LoansToApril2013,0,4):INDEX(LoansToApril2013,0,6)  

sum_range 值。

但是，如果我切換到使用 SUMIFS 來添加更多條件，如果使用索引范圍，Excel 將返回 #VALUE 錯誤。 它只接受一個索引。

=SUMIFS(INDEX(LoansToApril2013,0,4),INDEX(LoansToApril2013,0,3),1,INDEX(LoansToApril2013,0,1),"PTFBL") 

工作正常

=SUMIFS(INDEX(LoansToApril2013,0,4):INDEX(LoansToApril2013,0,6),INDEX(LoansToApril2013,0,3),1,INDEX(LoansToApril2013,0,1),"PTFBL")

返回#value，我不知道為什么。

有趣的是，

=SUMIFS(INDEX(LoansToApril2013,0,4):INDEX(LoansToApril2013,0,4),INDEX(LoansToApril2013,0,3),1,INDEX(LoansToApril2013,0,1),"PTFBL")

也被接受並返回與第一個具有單個索引的相同。

我找不到任何與此相關的文檔或評論。 有誰知道是否有一種替代結構可以讓 SUMIFS 有條件地對三列的索引值求和？ 我寧願不使用三個單獨的公式並將它們加在一起，盡管這是可能的。

Answer 1

sumifs公式是在數組公式之后建模的，並且sumifs比較需要具有相同的大小，最后一個模擬LoansToApril2013數組列4:4的單個列是第4:4列。

倒數第二個是 3 列寬，比較列是 1 列寬導致錯誤。

Answer 2

sumifs不能這樣做，但sumproduct可以

例子：

X  1  1  1
Y  2  2  2
Z  3  3  3

從 A1 開始

公式=SUMPRODUCT((A1:A3="X")*B1:D3)給出答案3 ，並將公式中的值X更改為Y或Z將返回值更改為適當的行的總和。
需要注意的是，如果你有在該地區的文本這是行不通的-它會返回#VALUE!

如果您無法避免文本，那么您需要一個數組公式。 使用相同的示例，公式為=SUM(IF(A1:A3="X",B1:D3)) ，要將其作為數組公式輸入，您需要使用CTRL + SHIFT + ENTER輸入公式- 您應該注意到 excel 將{ }放在公式周圍。 它將任何文本視為零，因此即使您在其中一個框中有文本，它也會成功地將找到的數字相加（例如，將示例中的1之一更改為blah ，總數將為 2 -公式將在行中添加兩個剩余的1 s）

Answer 3

上面的兩個答案和一些搜索讓我找到了一個有效的公式。 我會把它放在這里供后代使用，因為沒有最終結果的問題對未來的讀者來說是一種痛苦。

=SUMPRODUCT( (INDEX(LoansToApril2013,0,3)=C4) * (INDEX(LoansToApril2013,0,1)="PTFBL") * INDEX(LoansToApril2013,0,4):INDEX(LoansToApril2013,0,6))

這匯總了 LoansToApril2013 范圍的第 4-6 列中的值，其中第 3 列中的值等於 C4 中的值（又名“帶有公式的此單元格左側的單元格”），第 1 列中的值為“PTFBL ”。

盡管出現，它並沒有乘以任何其他東西。 我在這個頁面上找到了一個解釋，但基本上星號是為函數添加條件。 請注意，標准括在自己的括號中，而范圍則沒有。

Answer 4

如果要使用名稱范圍，則需要對索引命令使用 INDIRECT。

我使用該公式檢查兩列中的條件，然后將結果匯總到一個包含 12 列月份的表中（該列由 1 到 12 [L4] 的輔助單元格選擇）。

所以你可以這樣做：

部門（1列名稱范圍[C6]）=銷售[D6]； 區域（1 列名稱范圍 [C3]）= 美國 [D3]； 那些人/產品/行項目的 12 列每月命名范圍表 [E7] 中的 SUM 數字，用於該 1 個單月 [L4]

只需在您的報告頁面上復制公式，該頁面的第 1-12 列代表月份，您將獲得包含 2 個條件的月度總結報告。

=SUMPRODUCT((INDEX(INDIRECT($C$6),0,1)=$D$6) * (INDEX(INDIRECT($C$3),0,1)=$D$3) * INDEX(INDIRECT($E7) ,0,L$4))