Oracle：在整個數據庫中搜索字符串：錯誤ORA-00911

Question

我已經在下面創建了PL / SQL存儲過程，以在整個Oracle11g數據庫中搜索字符串（srchstr），並將找到該字符串的表和列返回到名為VALUESEARCHRESULTS的表中。

該過程已作為用戶通過SQL Developer在Oracle XE中成功運行。 但是，當嘗試在Oracle11g中以用戶SYS的身份針對架構ABC運行它時，出現以下錯誤：

ORA-00911：無效字符原因：標識符不能以字母和數字以外的任何ASCII字符開頭。 $＃_也允許在第一個字符之后。 用雙引號引起來的標識符可以包含除雙引號以外的任何字符。 替代引號（q“＃...＃”）不能使用空格，制表符或回車符作為分隔符。 對於所有其他上下文，請查閱《 SQL語言參考手冊》。

有誰知道為什么會這樣嗎？ 請在下面查看我的代碼。

CREATE OR REPLACE PROCEDURE ABC.FIND_STRING(p_str IN VARCHAR2) authid current_user is
  l_query    clob;
  srchstr    varchar2(30) := '';
  r_cname    varchar2(30) := '';
  l_case     clob;
  l_runquery boolean;
  l_tname    varchar2(30);
  l_cname    varchar2(30);
begin
   dbms_application_info.set_client_info( '%' || upper(p_str) || '%' );

   for x in (select * from user_tables)
   loop
       l_query := 'select ''' || x.table_name || ''', $$
                     from ' || x.table_name || '
                    where rownum = 1 and ( 1=0 ';
       l_case := 'case ';
       l_runquery := FALSE;
       for y in ( select *
                    from user_tab_columns
                   where table_name = x.table_name
                     and (data_type in('CHAR', 'DATE', 'FLOAT', 'NCHAR', 'NUMBER', 'NVARCHAR2', 'VARCHAR2' )
                       or data_type like 'INTERVAL%' or data_type like 'TIMESTAMP%' )
                )
       loop
           l_runquery := TRUE;
           l_query := l_query || ' or upper(' || y.column_name ||
                      ') like userenv(''client_info'') ';
           l_case := l_case || ' when upper(' || y.column_name ||
                     ') like userenv(''client_info'') then ''' ||
                     y.column_name || '''';
       end loop;
       if ( l_runquery )
       then
           l_case := l_case || ' else NULL end';
           l_query := replace( l_query, '$$', l_case ) || ')';
           begin
              execute immediate l_query into l_tname, l_cname;
              r_cname := l_cname;
              dbms_application_info.read_client_info(srchstr);
              insert into ABC.ValueSearchResults (resulttable, resultcolumn, searchstring) values (x.table_name, r_cname, srchstr);
               dbms_output.put_line
               ( srchstr || ' found in ' || l_tname || '.' || l_cname );
           exception
               when no_data_found then
                   dbms_output.put_line
                   ( srchstr || ' has no hits in ' || x.table_name );
           end;
          end if;
        end loop;
       end;

編輯 ：上面的存儲的過程編譯沒有錯誤。 下面的代碼通過將表中的值傳遞到存儲過程中來執行存儲過程。 該錯誤顯示何時運行以下代碼：

BEGIN
   FOR c IN (SELECT ControlValue FROM ABC.ControlValues) LOOP
       ABC.FIND_STRING(c.ControlValue);
   END LOOP;
END;

Answer 1

我已經找到了最初提出的問題的解決方案。

錯誤原因：未指定架構； 僅抓取用戶特定的表。

當存儲過程將以用戶ABC身份部署時將執行，而以用戶ABC身份運行存儲過程時將生成錯誤。 似乎在多個模式中存在相同的表名。 因此，添加OWNER變量可指定與表名關聯的架構，並消除了錯誤。

此外，該過程最初是在搜索USER_TABLES。 這將結果限制為僅當前模式的表。 通過用DBA_TABLES替換USER_TABLES，存儲過程的搜索遍及了數據庫的所有表。

請參閱下面的更正代碼：

CREATE OR REPLACE
PROCEDURE FIND_STRING(
    p_str IN VARCHAR2) authid current_user
IS
  l_query CLOB;
  srchstr VARCHAR2(100) := '';
  r_cname VARCHAR2(100) := '';
  l_case CLOB;
  l_runquery BOOLEAN;
  l_tname    VARCHAR2(100);
  l_cname    VARCHAR2(100);
BEGIN
  dbms_application_info.set_client_info( '%' || upper(p_str) || '%' );
  FOR x  IN
  (SELECT *
  FROM dba_tables
  WHERE table_name    <> 'CONTROLVALUES'
  AND table_name      <> 'VALUESEARCHRESULTS'
  AND tablespace_name <> 'SYSTEM'
  AND tablespace_name <> 'SYSAUX'
  AND tablespace_name <> 'TEMP'
  AND tablespace_name <> 'UNDOTBS1'
  )
  LOOP
    l_query    := 'select ''' || x.owner || '.' || x.table_name || ''', $$                         
from ' || x.owner || '.' || x.table_name || '                         
where rownum = 1 and ( 1=0 ';
    l_case     := 'case ';
    l_runquery := FALSE;
    FOR y  IN
    (SELECT *
    FROM dba_tab_columns
    WHERE table_name = x.table_name
    AND owner        = x.owner
    AND (data_type  IN ( 'CHAR', 'DATE', 'FLOAT', 'NCHAR', 'NUMBER', 'NVARCHAR2', 'VARCHAR2' )
    OR data_type LIKE 'INTERVAL%'
    OR data_type LIKE 'TIMESTAMP%' )
    )
    LOOP
      l_runquery := TRUE;
      l_query    := l_query || ' or upper(' || y.column_name || ') like userenv    (''client_info'') ';
      l_case     := l_case || ' when upper(' || y.column_name || ') like userenv    (''client_info'') then ''' || y.column_name || '''';
    END LOOP;
    IF ( l_runquery ) THEN
      l_case  := l_case || ' else NULL end';
      l_query := REPLACE( l_query, '$$', l_case ) || ')';
      BEGIN
        EXECUTE immediate l_query INTO l_tname, l_cname;
        r_cname := l_cname;
        dbms_application_info.read_client_info(srchstr);
        INSERT
        INTO VALUESEARCHRESULTS
          (
            resulttable,
            resultcolumn,
            searchstring
          )
          VALUES
          (
            x.table_name,
            r_cname,
            srchstr
          );
        dbms_output.put_line ( srchstr || ' found in ' || l_tname || '.' || l_cname );
      EXCEPTION
      WHEN no_data_found THEN
        dbms_output.put_line ( srchstr || ' has no hits in ' || x.owner || '.' || x.table_name );
      END;
    END IF;
  END LOOP;
END;