sumproduct excel多個表

Question

我有兩個表格，我想通過引用另一個表格來計算一個項目的出現次數，

例如，我想知道鮑勃擁有多少條蛇，顯而易見的答案是兩條，但是我如何用一個公式來做到這一點？ 我使用sumproduct來計算單個蛇的出現次數，但我希望通過引用第二張表將它們全部歸入一個公式。 這可能嗎？

注意 ：我有excel 2003，因此sumproduct

    A      B    
1  Bob    Boa
2  Ann    Cow
3  Bob    Sheep
4  Bob    Python

    A      B
1  Farm   Snake
2  Cow    Boa
3  Sheep  Python

Answer 1

當然，可以使用您現有的布局來執行此操作，而無需幫助器列。 假設A1:B4第一個表和D1:E3第二個表，您可以使用此公式獲得Bob擁有的蛇數

=SUMPRODUCT((A1:A4="Bob")*ISNUMBER(MATCH(B1:B4,INDEX(D2:E3,0, MATCH("snake",D1:E1,0)),0)))

我認為第一個標准是不言而喻的。

對於第二部分，此部分查找所有蛇名：

INDEX(D2:E3,0,MATCH("snake",D1:E1,0))

....因為它與D1：E1中的標頭匹配“蛇”，並返回下面的整個列[通過使用零作為INDEX中的行參數，您會得到整個列]。

然后，有了所有蛇名，您就可以使用MATCH來匹配它們。 如果匹配，則得到一個數字，否則，得到＃N / A，因此將MATCH函數包裝在ISNUMBER中以返回TRUE / FALSE。

另一種方法是使用COUNTIF代替ISNUMBER / MATCH

=SUMPRODUCT((A1:A4="Bob")*(COUNTIF(INDEX(D2:E3,0, MATCH("snake",D1:E1,0)),B1:B4)>0))

Answer 2

首先，您需要正確設置查找表。 無法按原樣查找第二個表。 首先將其更改如下：

Farm  Cow
Farm  Sheep
Snake Boa
Snake Python

現在，您可以使用以下公式查找事物的類型：

=INDEX(Sheet2!A:A,MATCH(B1,Sheet2!B:B,0))

如果將其添加到原始工作表的C列中，則會得到以下信息：

Bob Boa Snake
Ann Cow Farm
Bob Sheep   Farm
Bob Python  Snake

然后，您可以使用sumproduct：

=SUMPRODUCT((A1:A4="Bob")*(C1:C4="Snake"))