批處理文件輸出日期時間

Question

我正在創建一個批處理文件來運行一些備份。 但是，當我嘗試使用當前日期時間為文件命名時，結果卻很奇怪。

我正在使用：

backup.backup_%DATE:~10,4%%DATE:~7,2%%DATE:~4,2%_%time:~0,2%%time:~3,2%%time:~6,2%.backupfile

結果：backup.backup_0130-5-_101151.backupfile

有誰知道如何解決這一問題？

Answer 1

我認為您應該使用wmic而不是date和time來獲取當前日期和時間，而不受區域設置的影響

@echo off
SETLOCAL EnableDelayedExpansion


for /f "skip=1 tokens=1-6 delims= " %%a in ('wmic path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') do (
    IF NOT "%%~f"=="" (
        set /a FormattedDate=10000 * %%f + 100 * %%d + %%a
        set FormattedDate=!FormattedDate:~0,4!!FormattedDate:~-4,2!!FormattedDate:~2,2!
        set /a FormattedTime=%%b * 10000 + %%c * 100 + %%e
        set FormattedTime=!FormattedTime:~0,2!!FormattedTime:~-4,2!!FormattedTime:~-2,2!
    )
)

echo backup.backup_!FormattedDate!_!FormattedTime!
PAUSE

上面的代碼將以以下格式命名文件：

backup.backupYYYYMMDD_HHMMSS

例如backup.backup_20131013_163800

希望這可以幫助。

Answer 2

嘗試這個：

@ECHO OFF &SETLOCAL
for /f "skip=1delims=." %%a in ('wmic os get localdatetime') do if not defined DateTime set "DateTime=%%a"
echo(backup.backup_%DateTime:~0,8%_%DateTime:~8%

Answer 3

如果您必須在批處理文件中多次使用此功能，那么將其作為功能很好。 這可能會有所幫助：

:GetFileDateTime Format ret
@echo off & setlocal
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"
set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%.%Min%.%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%.%Min%.%Sec%"
( ENDLOCAL
    if /i "%~1"=="DT" set "%~2=%datestamp% %timestamp%"
    if /i "%~1"=="TD" set "%~2=%timestamp% %datestamp%" 
    if /i "%~1"=="D" set "%~2=%datestamp%"
    if /i "%~1"=="T" set "%~2=%timestamp%"
    if /i "%~1"=="F" set "%~2=%fullstamp%"
)
exit /b


Usage Example:

call :GetFileDateTime TD timedate
echo %timedate%

call :GetFileDateTime D date
echo %date%

Answer 4

我也建議Wmic for XP pro和更高版本。 我經常發布此代碼段：

該代碼的前四行將為您提供XP Pro及更高版本中可靠的YY DD MM YYYY HH Min Sec變量。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause