使用 VBA 宏對工作簿中的 Excel 表執行 SQL 查詢

Question

我正在嘗試制作一個 excel 宏，它將在 Excel 中提供以下 function：

=SQL("SELECT heading_1 FROM Table1 WHERE heading_2='foo'")

允許我使用 SQL 查詢在我的工作簿的表中搜索（甚至可能插入）數據。

這是我到目前為止所做的：

Sub SQL()

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon

strSQL = "SELECT * FROM [Sheet1$A1:G3]"

rs.Open strSQL, cn

Debug.Print rs.GetString

End Sub

我的腳本就像一個帶有硬編碼范圍的魅力，例如上面的代碼片段中的范圍。 它也適用於 static 命名范圍。

但是，它不適用於動態命名范圍或對我來說最重要的 TABLE NAMES。

我找到的最接近答案的是這個遭受同樣痛苦的人： http://www.ozgrid.com/forum/showthread.php?t=72973

幫助任何人？

編輯

到目前為止我已經完成了這個，然后我可以在我的 SQL 查詢中使用結果名稱。 限制是我需要知道表格在哪一張紙上。 我們能做點什么嗎？

Function getAddress()

    myAddress = Replace(Sheets("Sheet1").Range("Table1").address, "$", "")
    myAddress = "[Sheet1$" & myAddress & "]"

    getAddress = myAddress

End Function

謝謝！

Answer 1

您可以做的一件事是獲取動態命名范圍的地址，並將其用作SQL字符串中的輸入。 就像是：

Sheets("shtName").range("namedRangeName").Address

哪個會吐出一個地址字符串，比如$A$1:$A$8

編輯：

正如我在下面的評論中所說，您可以動態獲取完整地址（包括工作表名稱），並直接使用它或解析工作表名稱以供以后使用：

ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal

這導致字符串如=Sheet1!$C$1:$C$4 。 因此，對於上面的代碼示例，您的SQL語句可能是

strRangeAddress = Mid(ActiveWorkbook.Names.Item("namedRangeName").RefersToLocal,2)

strSQL = "SELECT * FROM [strRangeAddress]"

Answer 2

Public Function GetRange(ByVal sListName As String) As String

Dim oListObject As ListObject
Dim wb As Workbook
Dim ws As Worksheet

Set wb = ThisWorkbook

For Each ws In wb.Sheets
    For Each oListObject In ws.ListObjects
        If oListObject.Name = sListName Then
            GetRange = "[" & ws.Name & "$" & Replace(oListObject.Range.Address, "$", "") & "]"
        Exit Function
        End If
    Next oListObject
Next ws


End Function

在你的SQL中使用它就像這樣

sSQL = "Select * from " & GetRange("NameOfTable") & ""

Answer 3

基於Joan-Diego Rodriguez的Jordi方法和Jacek Kotowski代碼的一些例程 - 該函數將活動工作簿的任何表名轉換為SQL查詢的可用地址。

MikeL的注意事項：添加“[#All]”包括避免報告問題的標題。

Function getAddress(byVal sTableName as String) as String 

    With Range(sTableName & "[#All]")
        getAddress= "[" & .Parent.Name & "$" & .Address(False, False) & "]"
    End With

End Function

Answer 4

我是一個初學者修補別人的代碼，所以請寬容，並進一步糾正我的錯誤。 我嘗試了你的代碼，並使用VBA幫助以下工作：

Function currAddressTest(dataRangeTest As Range) As String

    currAddressTest = ActiveSheet.Name & "$" & dataRangeTest.Address(False, False)

End Function

當我為我的函數選擇數據源參數時，它將變為Sheet1 $ A1：G3格式。 如果excel將其更改為我的公式中的Table1 [#All]引用，則該函數仍然可以正常工作

然后我在你的函數中使用它（嘗試播放並添加另一個參數以注入WHERE ...

Function SQL(dataRange As Range, CritA As String)

Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim currAddress As String



currAddress = ActiveSheet.Name & "$" & dataRange.Address(False, False)

strFile = ThisWorkbook.FullName
strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
& ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")

cn.Open strCon


strSQL = "SELECT * FROM [" & currAddress & "]" & _
         "WHERE [A] =  '" & CritA & "'  " & _
         "ORDER BY 1 ASC"

rs.Open strSQL, cn

SQL = rs.GetString

End Function

希望你的功能進一步發展，我發現它非常有用。 祝你今天愉快！

Answer 5

只是想在這里添加，您可以將您的范圍設為一個命名范圍並在您的查詢中使用它（或者如果您每張紙有一個表，則使用整張紙）。

所以你可以使用：

SELECT * FROM MyNamedRange

或者

SELECT * FROM [Sheet1$]

很多這些答案似乎 go 解析地址的努力，而我過去所做的只是將我的所有表設置為命名范圍並直接在查詢中引用它們（也使它更清晰）。

在我下面的一個更復雜的查詢中，我引用的所有范圍都是命名范圍：

SELECT Unit_Type AS [Unit Type], COUNT(*) AS [Number of Units], SQFT, Deposit AS [Deposit{$}], Rent AS [Base Rent{$}], SUM(RENT) AS [Base Rent Total{$}], SUM(MR) AS [Market Rent Total{$}] FROM
(
    SELECT f1.Unit_Code, Unit_Type, SQFT, Rent, Deposit, SWITCH(MR IS NULL,Rent,MR IS NOT NULL,MR) AS MR FROM
    (   
        SELECT t2.Unit_Code, t2.Unit_Type, SQFT, Rent, Deposit FROM
        (
            SELECT DISTINCT Unit_Code, Unit_Type
            FROM CommUnits
            WHERE Unit_Code NOT LIKE "%WAIT%" AND Exclude=0
        ) t2
        LEFT JOIN
        (
            SELECT UnitType_Code, SQFT, Rent, Deposit
            FROM ResUnitTypes
        ) t1 ON (t1.UnitType_Code = t2.Unit_Type)
    ) f1
    LEFT JOIN
    (
        SELECT Unit_Code, SUM(Current_Charge) AS MR
        FROM ResUnitAmenities
        WHERE Unit_Code NOT LIKE "%WAIT%"
        GROUP BY Unit_Code
    ) f2 on (f1.Unit_Code = f2.Unit_Code)
)
GROUP BY Unit_Type, SQFT, Deposit, Rent

Answer 6

只需回答關於獲取表格所在表格名稱的問題的第二部分：

Dim name as String

name = Range("Table1").Worksheet.Name

編輯：

為了使事情更清楚：有人建議在Sheet對象上使用Range。 在這種情況下，你不需要; 可以使用表格的名稱獲取表格所在的范圍; 這個名字可以在整本書中找到。 所以，單獨調用Range效果很好。

Answer 7

嗨最近調查了這個並且在excel中引用了命名表（列表對象）的問題

如果你在表名上加一個后綴'$'，那么世界上一切都很好

Sub testSQL()

    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset

    ' Declare variables
    strFile = ThisWorkbook.FullName

    ' construct connection string
    strCon = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strFile _
    & ";Extended Properties=""Excel 12.0;HDR=Yes;IMEX=1"";"

    ' create connection and recordset objects
    Set cn = CreateObject("ADODB.Connection")
    Set rs = CreateObject("ADODB.Recordset")

    ' open connection
    cn.Open strCon

    ' construct SQL query
    strSQL = "SELECT * FROM [TableName$] where [ColumnHeader] = 'wibble';"

    ' execute SQL query
    rs.Open strSQL, cn

    Debug.Print rs.GetString

    ' close connection
    rs.Close
    cn.Close
    Set rs = Nothing
    Set cn = Nothing
End Sub

Answer 8

發現這個，它對我有用。

strSQL = "SELECT * FROM DataTable" 

'DataTable是指定范圍

如何在Excel工作表中的命名范圍上運行SQL語句？