對於哪些索引，索引使用情況統計表中沒有條目？

Question

我試圖找到哪些索引不用於清除它們並減少SQL Server索引維護。

所以，我已經設法根據官方文檔和其他文章（ 像這一個 ）提取兩個查詢：

第一個是基於sys.dm_db_index_usage_stats返回未使用的索引：

DECLARE @MinimumPageCount INT = 0

SELECT object_name(IDX.[object_id]) AS [Table]    
      ,IDX.[name] AS [Index] 
      ,PHS.[page_count] AS [Page_Count]
      ,CONVERT(DECIMAL(18,2), PHS.page_count * 8 / 1024.0) AS [Total Size (MB)]
      ,CONVERT(DECIMAL(18,2), PHS.avg_fragmentation_in_percent) AS [Frag %]
      ,PRS.row_count AS [Row Count]
      ,CONVERT(DECIMAL(18,2), (PHS.page_count * 8.0 * 1024) / PRS.row_count) AS [Index Size/Row (Bytes)]
      ,US.[user_updates]
      ,US.[last_user_update]
FROM [sys].[dm_db_index_usage_stats] US
INNER JOIN [sys].[indexes] IDX
    ON IDX.[index_id] = US.[index_id]
    AND IDX.[object_id] = US.[object_id]
INNER JOIN [sys].[dm_db_index_physical_stats] (DB_ID(),NULL,NULL,NULL,NULL) AS PHS
    ON PHS.[index_id] = US.[index_id] 
    AND PHS.[object_id] = US.[object_id]
INNER JOIN [sys].[dm_db_partition_stats] PRS
    ON PRS.[index_id] = US.[index_id]
    AND PRS.[object_id] = US.[object_id]  
WHERE 
    -- showing only not used indexes 
        US.[user_scans] = 0
    AND US.[user_seeks] = 0
    AND US.[user_lookups] = 0
    AND US.[system_scans] = 0
    AND US.[system_seeks] = 0
    AND US.[system_lookups] = 0
    -- ignore indexes with less than a certain number of pages of memory
    AND PHS.page_count > @MinimumPageCount
    -- exclude clustered and heaps tables
    AND US.[index_id] > 1
    --current db only 
    AND US.[database_id]= DB_ID()
ORDER BY [Page_Count] DESC

第二個是為sys.dm_db_index_usage_stats中沒有extries的索引提取類似信息，如下所示：

DECLARE @dbid INT =  DB_ID()

SELECT DB.Name AS [Database]
      ,OBJ.NAME AS [Table]
      ,IDX.NAME AS [Index]
      ,IDX.INDEX_ID
      ,PHS.page_count AS [Page Count]
      ,CONVERT(DECIMAL(18,2), PHS.page_count * 8 / 1024.0) AS [Total Index Size (MB)]
      ,CONVERT(DECIMAL(18,2), PHS.avg_fragmentation_in_percent) AS [Fragmentation (%)]
FROM [sys].[indexes] IDX
INNER JOIN SYS.OBJECTS OBJ 
    ON IDX.[object_id] = OBJ.[object_id]
LEFT JOIN [sys].[dm_db_index_physical_stats] (@dbid, NULL, NULL, NULL, NULL) PHS
    ON PHS.[object_id] = IDX.[object_id] 
    AND PHS.[index_id] = IDX.[index_id]
INNER JOIN [sys].[databases] DB
    ON DB.[database_id] = PHS.[database_id]
WHERE OBJ.[type] = 'U' -- Is User Table
    AND IDX.[is_primary_key] = 0
    AND IDX.[index_id] NOT IN 
    (
        SELECT US.INDEX_ID
        FROM [sys].[dm_db_index_usage_stats] US
        WHERE US.[object_id] = IDX.[object_id]
            AND IDX.[index_id] = US.[index_id]
            AND [database_id] = @dbid
    )
    AND IDX.[index_id] > 1
ORDER BY PHS.[page_count] DESC
        ,OBJ.[name]
        ,IDX.[index_id]
        ,IDX.[name] ASC

查看上面的查詢，唯一的過濾是基於sys.dm_db_index_usage_stats是否存在特定索引的條目。

那么，是否存在一條規則，即如果沒有條目，則不使用索引？

Answer 1

您提供的第一個查詢搜索未使用的索引。 sys.dm_db_index_usage_stats函數具有[user_scans]，[user_seeks]，[user_lookups]，[system_scans]，[system_seeks]，[system_lookups]字段。 如果它們都是0，則根據您自己的鏈接，這意味着從未使用過索引。

第二個查詢給出了沒有可用的使用統計信息的索引。 根據您的鏈接，sys.dm_db_index_usage_stats函數的記錄在每次重新啟動時都設置為零，並在數據庫分離或關閉時刪除。 因此，如果從數據庫分離或關閉后從未使用過索引，那么就不會有使用統計行。

你已經給出了這個鏈接，但為了完整答案，我再次給它： http ： //technet.microsoft.com/en-us/library/ms188755.aspx